mirror of
https://git.yoctoproject.org/poky
synced 2026-06-01 13:09:50 +00:00
Tim Orling
b6a3c9c298
[YOCTO #10005] Krogoth-next checkuri failures
From Ross Burton (commit 1d39e4c145)
Using ${DEBIAN_MIRROR} for SRC_URI doesn't work very well as that will only contain releases that are currently in Debian, so currently doesn't contain 1.18.4 as unstable has moved on to 1.18.9.
So, move all of SRC_URI to the .bb so it can use snapshot.debian.org instead, and set UPSTREAM_CHECK_URI to ${DEBIAN_MIRROR} so upstream release checking continues to work.
(From OE-Core rev: 85378ebe19730cc42587bf1e5e5e15b3deda638b)
Signed-off-by: Tim Orling <timothy.t.orling@linux.intel.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
2.5 KiB
PHP
80 lines
2.5 KiB
PHP
SUMMARY = "Package maintenance system from Debian"
|
|
LICENSE = "GPLv2.0+"
|
|
SECTION = "base"
|
|
|
|
SRC_URI_append_class-native = " file://0001-When-running-do_package_write_deb-we-have-trees-of-h.patch"
|
|
|
|
DEPENDS = "zlib bzip2 perl ncurses"
|
|
DEPENDS_class-native = "bzip2-replacement-native zlib-native virtual/update-alternatives-native gettext-native perl-native"
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} xz run-postinsts perl"
|
|
RDEPENDS_${PN}_class-native = "xz-native"
|
|
|
|
UPSTREAM_CHECK_URI = "${DEBIAN_MIRROR}/main/d/dpkg/"
|
|
|
|
inherit autotools gettext perlnative pkgconfig systemd
|
|
|
|
python () {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
pn = d.getVar('PN', True)
|
|
d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'dpkg-configure.service')
|
|
}
|
|
|
|
export PERL = "${bindir}/perl"
|
|
PERL_class-native = "${STAGING_BINDIR_NATIVE}/perl-native/perl"
|
|
|
|
export PERL_LIBDIR = "${libdir}/perl"
|
|
PERL_LIBDIR_class-native = "${libdir}/perl-native/perl"
|
|
|
|
EXTRA_OECONF = "\
|
|
--disable-dselect \
|
|
--enable-start-stop-daemon \
|
|
--with-zlib \
|
|
--with-bz2 \
|
|
--without-liblzma \
|
|
--without-selinux \
|
|
"
|
|
|
|
EXTRA_OECONF += "TAR=tar"
|
|
|
|
do_configure () {
|
|
echo >> ${S}/m4/compiler.m4
|
|
sed -i -e 's#PERL_LIBDIR=.*$#PERL_LIBDIR="${libdir}/perl"#' ${S}/configure
|
|
autotools_do_configure
|
|
}
|
|
|
|
do_install_append () {
|
|
if [ "${PN}" = "dpkg-native" ]; then
|
|
# update-alternatives doesn't have an offline mode
|
|
rm ${D}${bindir}/update-alternatives
|
|
sed -i -e 's|^#!.*${bindir}/perl-native.*/perl|#!/usr/bin/env nativeperl|' ${D}${bindir}/dpkg-*
|
|
else
|
|
sed -i -e 's|^#!.*${bindir}/perl-native.*/perl|#!/usr/bin/env perl|' ${D}${bindir}/dpkg-*
|
|
fi
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${WORKDIR}/dpkg-configure.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
|
|
-e 's,@SYSCONFDIR@,${sysconfdir},g' \
|
|
-e 's,@BINDIR@,${bindir},g' \
|
|
-e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
|
|
${D}${systemd_unitdir}/system/dpkg-configure.service
|
|
fi
|
|
}
|
|
|
|
PROV = "virtual/update-alternatives"
|
|
PROV_class-native = ""
|
|
|
|
PROVIDES += "${PROV}"
|
|
|
|
PACKAGES =+ "update-alternatives-dpkg"
|
|
FILES_update-alternatives-dpkg = "${bindir}/update-alternatives ${localstatedir}/lib/dpkg/alternatives ${sysconfdir}/alternatives"
|
|
RPROVIDES_update-alternatives-dpkg += "update-alternatives"
|
|
|
|
PACKAGES += "${PN}-perl"
|
|
FILES_${PN}-perl = "${libdir}/perl"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
|