mirror of
https://git.yoctoproject.org/poky
synced 2026-07-16 03:47:03 +00:00
Peter Kjellerstedt
084c70344f
The soup.cross file is only created when building for target so only tell meson to read it when it exists. This allows libsoup-native to be built again. (From OE-Core rev: ae1893565bdd2597a08df6ac41db40641da66712) Signed-off-by: Peter Kjellerstedt <peter.kjellerstedt@axis.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
2.2 KiB
BlitzBasic
60 lines
2.2 KiB
BlitzBasic
SUMMARY = "An HTTP library implementation in C"
|
|
DESCRIPTION = "libsoup is an HTTP client/server library for GNOME. It uses GObjects \
|
|
and the glib main loop, to integrate well with GNOME applications."
|
|
HOMEPAGE = "https://wiki.gnome.org/Projects/libsoup"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
SECTION = "x11/gnome/libs"
|
|
LICENSE = "LGPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native libxml2 sqlite3 libpsl nghttp2"
|
|
|
|
SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/libsoup/${SHRT_VER}/libsoup-${PV}.tar.xz"
|
|
SRC_URI[sha256sum] = "78c8fa37cb152d40ec8c4a148d6155e2f6947f3f1602a7cda3a31ad40f5ee2f3"
|
|
|
|
PROVIDES = "libsoup-3.0"
|
|
CVE_PRODUCT = "libsoup"
|
|
|
|
S = "${WORKDIR}/libsoup-${PV}"
|
|
|
|
inherit meson gettext pkgconfig upstream-version-is-even gobject-introspection gi-docgen
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[brotli] = "-Dbrotli=enabled,-Dbrotli=disabled,brotli"
|
|
PACKAGECONFIG[gssapi] = "-Dgssapi=enabled,-Dgssapi=disabled,krb5"
|
|
PACKAGECONFIG[ntlm] = "-Dntlm=enabled,-Dntlm=disabled"
|
|
PACKAGECONFIG[sysprof] = "-Dsysprof=enabled,-Dsysprof=disabled,sysprof"
|
|
|
|
# Tell libsoup where the target ntlm_auth is installed
|
|
do_write_config:append:class-target() {
|
|
cat >${WORKDIR}/soup.cross <<EOF
|
|
[binaries]
|
|
ntlm_auth = '${bindir}/ntlm_auth'
|
|
EOF
|
|
}
|
|
EXTRA_OEMESON:append:class-target = " --cross-file ${WORKDIR}/soup.cross"
|
|
|
|
EXTRA_OEMESON += "-Dvapi=disabled -Dtls_check=false"
|
|
# Disable the test suites
|
|
EXTRA_OEMESON += "-Dtests=false -Dautobahn=disabled -Dpkcs11_tests=disabled"
|
|
|
|
GIDOCGEN_MESON_OPTION = 'docs'
|
|
GIDOCGEN_MESON_ENABLE_FLAG = 'enabled'
|
|
GIDOCGEN_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
# When built without gnome support, libsoup will contain only one shared lib
|
|
# and will therefore become subject to renaming by debian.bbclass. Prevent
|
|
# renaming in order to keep the package name consistent regardless of whether
|
|
# gnome support is enabled or disabled.
|
|
DEBIAN_NOAUTONAME:${PN} = "1"
|
|
|
|
# glib-networking is needed for SSL, proxies, etc.
|
|
RRECOMMENDS:${PN} = "glib-networking"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|