mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 00:39:46 +00:00
Richard Purdie
23d9886aae
Absolute path symlinks are a bit of a pain for sstate and the native versions of these recipes currently contain broken symlinks as a result. There are only a small number of problematic recipes, at least in OE-Core, namely the three here. Rather than trying to make sstate handle this magically, which turns out to be a harder problem than you'd first realise, simply make the symlinks relative early in the process and avoid all the problems. The alternative is adding new complexity to sstate which we could really do without as without the complexity, you can't always tell where the absolute symlink is relative to (due to prefixes used for native sstate). (From OE-Core rev: e478550c8cd889f12e336e268e9e3b30827bf840) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.7 KiB
BlitzBasic
46 lines
1.7 KiB
BlitzBasic
SUMMARY = "Very high-quality data compression program"
|
|
DESCRIPTION = "bzip2 compresses files using the Burrows-Wheeler block-sorting text compression algorithm, and \
|
|
Huffman coding. Compression is generally considerably better than that achieved by more conventional \
|
|
LZ77/LZ78-based compressors, and approaches the performance of the PPM family of statistical compressors."
|
|
HOMEPAGE = "http://www.bzip.org/"
|
|
SECTION = "console/utils"
|
|
LICENSE = "bzip2"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;beginline=8;endline=37;md5=40d9d1eb05736d1bfc86cfdd9106e6b2"
|
|
PR = "r5"
|
|
|
|
SRC_URI = "http://www.bzip.org/${PV}/${BP}.tar.gz \
|
|
file://fix-bunzip2-qt-returns-0-for-corrupt-archives.patch \
|
|
file://configure.ac;subdir=${BP} \
|
|
file://Makefile.am;subdir=${BP} \
|
|
file://run-ptest \
|
|
file://CVE-2016-3189.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "00b516f4704d4a7cb50a1d97e6e8e15b"
|
|
SRC_URI[sha256sum] = "a2848f34fcd5d6cf47def00461fcb528a0484d8edef8208d6d2e2909dc61d9cd"
|
|
|
|
UPSTREAM_CHECK_URI = "http://www.bzip.org/downloads.html"
|
|
|
|
PACKAGES =+ "libbz2"
|
|
|
|
CFLAGS_append = " -fPIC -fpic -Winline -fno-strength-reduce -D_FILE_OFFSET_BITS=64"
|
|
|
|
inherit autotools update-alternatives ptest relative_symlinks
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_${PN} = "bunzip2 bzcat"
|
|
|
|
#install binaries to bzip2-native under sysroot for replacement-native
|
|
EXTRA_OECONF_append_class-native = " --bindir=${STAGING_BINDIR_NATIVE}/${PN}"
|
|
|
|
do_install_ptest () {
|
|
cp -f ${B}/Makefile ${D}${PTEST_PATH}/Makefile
|
|
sed -i -e "s|^Makefile:|_Makefile:|" ${D}${PTEST_PATH}/Makefile
|
|
}
|
|
|
|
FILES_libbz2 = "${libdir}/lib*${SOLIBS}"
|
|
|
|
PROVIDES_append_class-native = " bzip2-replacement-native"
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|