mirror of
https://git.yoctoproject.org/poky
synced 2026-07-16 03:47:03 +00:00
Anil Dongare
d144337355
- Pick the upstream patch [1] as mentioned in [2] and [3]. - To successfully apply the fixed commit, apply the dependent commits [4], which are included in v1.0.28. [1] https://github.com/libusb/libusb/commit/bc0886173ea15b8cc9bba2918f58a97a7f185231 [2] https://security-tracker.debian.org/tracker/CVE-2026-23679. [3] https://security-tracker.debian.org/tracker/CVE-2026-47104. [4] https://github.com/libusb/libusb/commit/016a0de33ac94b19c7772d6c20fbea7fec23bf68 (From OE-Core rev: c4d5735228e83c3a9afce48a39707b2ff5460fde) Signed-off-by: Anil Dongare <adongare@cisco.com> Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev>
53 lines
1.5 KiB
BlitzBasic
53 lines
1.5 KiB
BlitzBasic
SUMMARY = "Userspace library to access USB (version 1.0)"
|
|
DESCRIPTION = "A cross-platform library to access USB devices from Linux, \
|
|
macOS, Windows, OpenBSD/NetBSD, Haiku and Solaris userspace."
|
|
HOMEPAGE = "https://libusb.info"
|
|
BUGTRACKER = "http://www.libusb.org/report"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
CVE_PRODUCT = "libusb"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/libusb-${PV}.tar.bz2 \
|
|
file://run-ptest \
|
|
file://CVE-2026-23679_CVE-2026-47104-dependent.patch \
|
|
file://CVE-2026-23679_CVE-2026-47104.patch \
|
|
"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/libusb/libusb/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
|
|
|
|
SRC_URI[sha256sum] = "ffaa41d741a8a3bee244ac8e54a72ea05bf2879663c098c82fc5757853441575"
|
|
|
|
S = "${WORKDIR}/libusb-${PV}"
|
|
|
|
inherit autotools pkgconfig ptest github-releases
|
|
|
|
PACKAGECONFIG:class-target ??= "udev"
|
|
PACKAGECONFIG[udev] = "--enable-udev,--disable-udev,udev"
|
|
|
|
EXTRA_OECONF = "--libdir=${base_libdir}"
|
|
|
|
do_install:append() {
|
|
install -d ${D}${libdir}
|
|
if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
|
|
mv ${D}${base_libdir}/pkgconfig ${D}${libdir}
|
|
fi
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests stress
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -m 755 ${B}/tests/stress ${D}${PTEST_PATH}
|
|
}
|
|
|
|
FILES:${PN} += "${base_libdir}/*.so.*"
|
|
|
|
FILES:${PN}-dev += "${base_libdir}/*.so ${base_libdir}/*.la"
|