mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 12:49:46 +00:00
Khem Raj
79253a5668
Bring following changes on top of 1.2.5 * dd1e63c3 syslog: revert LOG_FAC/LOG_FACMASK changes * 008f737d siglongjmp: document why this function just calls longjmp * 947b4574 inet_ntop: fix the IPv6 leading zero sequence compression * 50ab8306 dynlink: avoid copying to temp buffer in get_lfs64 * 1b97d006 sys/epoll.h: add epoll ioctls * ab31e9d6 getusershell: skip blank lines and comments * 53ac44ff dynlink: fix get_lfs64() with posix_fallocate64 * 895736d4 syslog: fix incorrect LOG_MAKEPRI and LOG_FAC[MASK] macros * 05ce67fe add renameat2 linux syscall wrapper * 00799729 fix mismatched type in posix_getdents definition * cbf59dd6 aarch64 crti.o: fix alignment of _init/_fini * 84015cee fix typo that broke sys/reg.h and sys/user.h * 1b0d4851 implement posix_getdents adopted for next issue of POSIX * 2c124e13 stdint.h: derive limits from __LONG_MAX, use common fast16 types * 7019fbe1 sys/user.h: derive __WORDSIZE from __LONG_MAX * e709a6f0 sys/reg.h: derive __WORDSIZE from __LONG_MAX * 29b216b2 unistd.h: derive ILP32/LP64 macros from __LONG_MAX instead of arch bits * 0dfa1d8c unify bits/stat.h for all archs sharing a common definition * ef600888 align aarch64, riscv64, loongarch64 stat structure padding type * 6f666231 ldso: fix non-functional fix to early dynamic PAGE_SIZE access * fced99e9 strptime: implement conversion specifiers adopted for next POSIX issue * 3f9d4224 printf decimal integer formatting: shave off one division * a23cf8f9 riscv mcontext_t/sigcontext: use __aligned__ instead of aligned * cbf1c7b6 add missing STATX_ATTR_* macros omitted when statx was added * 3f49203c initgroups: do not artificially limit number of supplementary groups * 24ebbbde printf: fix edge case where hex float precision was not honored * e3b0ace5 complex: fix comment in cacosh * 9683bd62 math: fix fma(x,y,0) when x*y rounds to -0 * 5370070f fix pwrite/pwritev handling of O_APPEND files * bdc9a9ff uio.h: add RWF_NOAPPEND flag for pwritev2 * 7ada6dde iconv: fix missing bounds checking for shift_jis decoding * fd7d0185 add missing inline keyword on default a_barrier definition * b5121e2e iconv: add aliases for GBK * ca6f46af iconv: add euro symbol to GBK as single byte 0x80 (From OE-Core rev: 70179bc94c90ba1f33a3fff8f3019cb96fcdbaef) (From OE-Core rev: bcfaa9542fac82e90fbb8bdf67e3ade2697fbca4) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
86 lines
2.8 KiB
BlitzBasic
86 lines
2.8 KiB
BlitzBasic
# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
require musl.inc
|
|
inherit linuxloader
|
|
|
|
SRCREV = "dd1e63c3638d5f9afb857fccf6ce1415ca5f1b8b"
|
|
|
|
BASEVER = "1.2.5"
|
|
|
|
PV = "${BASEVER}+git"
|
|
|
|
SRC_URI = "git://git.musl-libc.org/musl;branch=master \
|
|
file://0001-Make-dynamic-linker-a-relative-symlink-to-libc.patch \
|
|
file://0002-ldso-Use-syslibdir-and-libdir-as-default-pathes-to-l.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PROVIDES += "virtual/libc virtual/libiconv virtual/libintl virtual/crypt"
|
|
|
|
DEPENDS = "virtual/${TARGET_PREFIX}binutils \
|
|
virtual/${TARGET_PREFIX}gcc \
|
|
libgcc-initial \
|
|
linux-libc-headers \
|
|
bsd-headers \
|
|
libssp-nonshared \
|
|
"
|
|
GLIBC_LDSO = "${@get_glibc_loader(d)}"
|
|
MUSL_LDSO_ARCH = "${@get_musl_loader_arch(d)}"
|
|
|
|
export CROSS_COMPILE="${TARGET_PREFIX}"
|
|
|
|
LDFLAGS += "-Wl,-soname,libc.so"
|
|
|
|
# When compiling for Thumb or Thumb2, frame pointers _must_ be disabled since the
|
|
# Thumb frame pointer in r7 clashes with musl's use of inline asm to make syscalls
|
|
# (where r7 is used for the syscall NR). In most cases, frame pointers will be
|
|
# disabled automatically due to the optimisation level, but append an explicit
|
|
# -fomit-frame-pointer to handle cases where optimisation is set to -O0 or frame
|
|
# pointers have been enabled by -fno-omit-frame-pointer earlier in CFLAGS, etc.
|
|
CFLAGS:append:arm = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}"
|
|
|
|
CONFIGUREOPTS = " \
|
|
--prefix=${prefix} \
|
|
--exec-prefix=${exec_prefix} \
|
|
--bindir=${bindir} \
|
|
--libdir=${libdir} \
|
|
--includedir=${includedir} \
|
|
--syslibdir=${nonarch_base_libdir} \
|
|
"
|
|
|
|
do_configure() {
|
|
${S}/configure ${CONFIGUREOPTS}
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR='${D}'
|
|
install -d ${D}${bindir} ${D}${sysconfdir}
|
|
echo "${base_libdir}" > ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
|
|
echo "${libdir}" >> ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
|
|
rm -f ${D}${bindir}/ldd ${D}${GLIBC_LDSO}
|
|
ln -rs ${D}${libdir}/libc.so ${D}${bindir}/ldd
|
|
}
|
|
|
|
FILES:${PN} += "${nonarch_base_libdir}/ld-musl-${MUSL_LDSO_ARCH}.so.1 ${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path"
|
|
FILES:${PN}-staticdev = "${libdir}/libc.a"
|
|
FILES:${PN}-dev =+ "${libdir}/libcrypt.a ${libdir}/libdl.a ${libdir}/libm.a \
|
|
${libdir}/libpthread.a ${libdir}/libresolv.a \
|
|
${libdir}/librt.a ${libdir}/libutil.a ${libdir}/libxnet.a \
|
|
"
|
|
|
|
RDEPENDS:${PN}-dev += "linux-libc-headers-dev bsd-headers-dev libssp-nonshared-staticdev"
|
|
RPROVIDES:${PN}-dev += "libc-dev virtual-libc-dev"
|
|
RPROVIDES:${PN} += "ldd rtld(GNU_HASH)"
|
|
|
|
LEAD_SONAME = "libc.so"
|
|
INSANE_SKIP:${PN}-dev = "staticdev"
|
|
INSANE_SKIP:${PN} = "libdir"
|
|
|
|
UPSTREAM_CHECK_COMMITS = "1"
|