mirror of
https://git.yoctoproject.org/poky
synced 2026-06-01 13:09:50 +00:00
Xiangyu Chen
d55092f458
The following commit has been backported into the 6.6.y branch.
See upstream commit:
commit 5fe6ec8f6ab549b6422e41551abb51802bd48bc7
Author: Peter Zijlstra <peterz@infradead.org>
Date: Mon Nov 6 13:41:43 2023 +0100
sched: Remove vruntime from trace_sched_stat_runtime()
That caused building the lttng-modules report compile error:
tracepoint-event-impl.h:133:6: error: conflicting types for
'trace_sched_stat_runtime';
The fix is still pending on lttng review board, backport it to oe-core to
de-block the build issue.
(From OE-Core rev: 0562a2c75985acf9ef33034e8aeb163afdc683bf)
Signed-off-by: Xiangyu Chen <xiangyu.chen@windriver.com>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit 5b973be9a7fbb2694d162ac06b76513525f3deed)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
50 lines
2.1 KiB
BlitzBasic
50 lines
2.1 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPL-2.1-only & GPL-2.0-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=8d0d9f08888046474772a5d745d89d6a"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://0001-Fix-kfree_skb-changed-in-6.11-rc1.patch \
|
|
file://0002-Fix-ext4_da_reserve_space-changed-in-6.11-rc1.patch \
|
|
file://0003-Fix-orig_start-removed-from-btrfs_get_extent-in-6.11.patch \
|
|
file://0004-Fix-block_len-removed-frmo-btrfs_get_extent-in-6.11-.patch \
|
|
file://0005-Fix-block_start-removed-from-btrfs_get_extent-in-6.1.patch \
|
|
file://0006-Fix-scsi-sd-Atomic-write-support-added-in-6.11-rc1.patch \
|
|
"
|
|
|
|
# Use :append here so that the patch is applied also when using devupstream
|
|
SRC_URI:append = " file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch \
|
|
file://0001-Fix-sched_stat_runtime-changed-in-Linux-6.6.66.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "c6449f7ff12ab644a630692a556304e51525ca37d98aebf826796918be0f5da6"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
MODULES_MODULE_SYMVERS_LOCATION = "src"
|
|
|
|
do_install:append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
if [ -d ${D}/${nonarch_base_libdir} ]; then
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
fi
|
|
}
|
|
|
|
python do_package:prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRC_URI:class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13;protocol=https"
|
|
SRCREV:class-devupstream = "7584cfc04914cb0842a986e9808686858b9c8630"
|
|
SRCREV_FORMAT ?= "lttng_git"
|