mirror of
https://git.yoctoproject.org/poky
synced 2026-06-01 13:09:50 +00:00
Wang Mingyu
3516ceb189
ptest.patch refreshed for 1.24. Changelog: =========== * New gdbm_load option: --update * Fix semantics of gdbm_load -r * Use getline in gdbmtool shell. * New function: gdbm_load_from_file_ext * Fix binary dump format for key and/or data of zero size. * Fix location tracking and recover command in gdbtool. * Fix possible buffer underflow in gdbmload. * Ensure any padding bytes in avail_elem structure are filled with 0. * Improve the documentation. (From OE-Core rev: 458fda9cc5f871e200bcd33ed33fda4a0ed46ff4) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.4 KiB
BlitzBasic
46 lines
1.4 KiB
BlitzBasic
SUMMARY = "Key/value database library with extensible hashing"
|
|
DESCRIPTION = "Library of database functions that use extensible hashing \
|
|
and work similar to the standard UNIX dbm. These routines are provided \
|
|
to a programmer needing to create and manipulate a hashed database."
|
|
HOMEPAGE = "http://www.gnu.org/software/gdbm/"
|
|
SECTION = "libs"
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=241da1b9fe42e642cbb2c24d5e0c4d24"
|
|
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gdbm/gdbm-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://ptest.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "695e9827fdf763513f133910bc7e6cfdb9187943a4fec943e57449723d2b8dbf"
|
|
|
|
inherit autotools gettext texinfo lib_package ptest
|
|
|
|
# Needed for dbm python module
|
|
EXTRA_OECONF = "--enable-libgdbm-compat --without-readline"
|
|
|
|
# Stop presence of dbm/nbdm on the host contaminating builds
|
|
CACHED_CONFIGUREVARS += "ac_cv_lib_ndbm_main=no ac_cv_lib_dbm_main=no"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_install:append () {
|
|
# Create a symlink to ndbm.h and gdbm.h in include/gdbm to let other packages to find
|
|
# these headers
|
|
install -d ${D}${includedir}/gdbm
|
|
ln -sf ../ndbm.h ${D}/${includedir}/gdbm/ndbm.h
|
|
ln -sf ../gdbm.h ${D}/${includedir}/gdbm/gdbm.h
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "diffutils ${PN}-bin"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests buildtests
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-compat \
|
|
"
|
|
FILES:${PN}-compat = "${libdir}/libgdbm_compat${SOLIBS} \
|
|
"
|