mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 00:39:46 +00:00
Wang Mingyu
524f0d5b57
Changelog: ========== * Allow HTTP/2 to be used with non-HTTP proxies * Strictly forbid NUL bytes in headers * Fix minor leaks * Add 'SOUP_METHOD_PATCH' * websocket: Add 'SoupWebsocketConnection:keepalive-pong-timeout' property * Increase maxmimum size of HTTP headers * Fix 'soup_uri_copy()' in Vala * Fix leak in 'soup_message_new_from_encoded_form()' * multipart: Improve handling of messages missing termination * logger: Fix request filter function being called with response user data * logger: Fix response bodies never being logged if request bodies aren't * logger: Add Soup-Host to logged headers for when Host is missing * cookies: Fix incorrect logic in determining same-site cookies * cookie-jar-db: Explicitly handle old databases lacking same-site column * cookies: Limit the Max-Age to 1 year (From OE-Core rev: f879d942d4b980a59b1000c1b0710282e08991f5) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
2.1 KiB
BlitzBasic
60 lines
2.1 KiB
BlitzBasic
SUMMARY = "An HTTP library implementation in C"
|
|
DESCRIPTION = "libsoup is an HTTP client/server library for GNOME. It uses GObjects \
|
|
and the glib main loop, to integrate well with GNOME applications."
|
|
HOMEPAGE = "https://wiki.gnome.org/Projects/libsoup"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
SECTION = "x11/gnome/libs"
|
|
LICENSE = "LGPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native libxml2 sqlite3 libpsl nghttp2"
|
|
|
|
SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/libsoup/${SHRT_VER}/libsoup-${PV}.tar.xz"
|
|
SRC_URI[sha256sum] = "62959f791e8e8442f8c13cedac8c4919d78f9120d5bb5301be67a5e53318b4a3"
|
|
|
|
PROVIDES = "libsoup-3.0"
|
|
CVE_PRODUCT = "libsoup"
|
|
|
|
S = "${WORKDIR}/libsoup-${PV}"
|
|
|
|
inherit meson gettext pkgconfig upstream-version-is-even gobject-introspection gi-docgen vala
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[brotli] = "-Dbrotli=enabled,-Dbrotli=disabled,brotli"
|
|
PACKAGECONFIG[gssapi] = "-Dgssapi=enabled,-Dgssapi=disabled,krb5"
|
|
PACKAGECONFIG[ntlm] = "-Dntlm=enabled,-Dntlm=disabled"
|
|
PACKAGECONFIG[sysprof] = "-Dsysprof=enabled,-Dsysprof=disabled,sysprof"
|
|
|
|
# Tell libsoup where the target ntlm_auth is installed
|
|
do_write_config:append:class-target() {
|
|
cat >${WORKDIR}/soup.cross <<EOF
|
|
[binaries]
|
|
ntlm_auth = '${bindir}/ntlm_auth'
|
|
EOF
|
|
}
|
|
EXTRA_OEMESON:append:class-target = " --cross-file ${WORKDIR}/soup.cross"
|
|
|
|
EXTRA_OEMESON += "-Dtls_check=false"
|
|
# Disable the test suites
|
|
EXTRA_OEMESON += "-Dtests=false -Dautobahn=disabled -Dpkcs11_tests=disabled"
|
|
|
|
GIDOCGEN_MESON_OPTION = 'docs'
|
|
GIDOCGEN_MESON_ENABLE_FLAG = 'enabled'
|
|
GIDOCGEN_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
# When built without gnome support, libsoup will contain only one shared lib
|
|
# and will therefore become subject to renaming by debian.bbclass. Prevent
|
|
# renaming in order to keep the package name consistent regardless of whether
|
|
# gnome support is enabled or disabled.
|
|
DEBIAN_NOAUTONAME:${PN} = "1"
|
|
|
|
# glib-networking is needed for SSL, proxies, etc.
|
|
RRECOMMENDS:${PN} = "glib-networking"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|