mirror of
https://git.yoctoproject.org/poky
synced 2026-07-16 03:47:03 +00:00
Richard Purdie
4ec1e60607
This solves ptest runtime errors where make was missing causing the ptests to fail. (From OE-Core rev: 47bcd4dec32e87b7353b079f63931d11cd0568e6) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> [Fixup for warrior context] [Dropped ptest fixes for pkg w/o ptests in warrior] Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.4 KiB
PHP
47 lines
1.4 KiB
PHP
SUMMARY = "Utilities for manipulating filesystem extended attributes"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/attr/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "virtual/libintl"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=2d0aa14b3fce4694e4f615e30186335f \
|
|
file://attr/attr.c;endline=17;md5=be0403261f0847e5f43ed5b08d19593c \
|
|
file://libattr/libattr.c;endline=17;md5=7970f77049f8fa1199fff62a7ab724fb"
|
|
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/attr/${BP}.src.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
require ea-acl.inc
|
|
|
|
# libdir should point to .la
|
|
do_install_append() {
|
|
sed -i ${D}${libdir}/libattr.la -e \
|
|
s,^libdir=\'${base_libdir}\'$,libdir=\'${libdir}\',
|
|
}
|
|
|
|
inherit ptest update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_${PN} = "setfattr"
|
|
ALTERNATIVE_TARGET[setfattr] = "${bindir}/setfattr"
|
|
|
|
PTEST_BUILD_HOST_FILES = "builddefs"
|
|
PTEST_BUILD_HOST_PATTERN = "^RPM"
|
|
|
|
do_install_ptest() {
|
|
tar -c --exclude=ext test/ | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
mkdir ${D}${PTEST_PATH}/include
|
|
for i in builddefs buildmacros buildrules; \
|
|
do cp ${S}/include/$i ${D}${PTEST_PATH}/include/; \
|
|
done
|
|
sed -e 's|; @echo|; echo|' -i ${D}${PTEST_PATH}/test/Makefile
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "attr coreutils perl-module-filehandle perl-module-getopt-std perl-module-posix make"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|