mirror of
https://git.yoctoproject.org/poky
synced 2026-07-21 05:27:01 +00:00
Sumit Garg
b3d2fb6ab1
Some native tools dependency issues were seen while building with external GCC tool-set rather than source GCC tool-set. While building with source tool-set these dependencies were implicitly met which is not the case with external tool-set. So explicitly state these native tools dependencies. (From OE-Core rev: 534b4a63299c6d74662c9d035238a0adb19cd1c7) Signed-off-by: Sumit Garg <sumit.garg@linaro.org> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
1.8 KiB
PHP
58 lines
1.8 KiB
PHP
SUMMARY = "Utilities for managing processes on your system"
|
|
HOMEPAGE = "http://psmisc.sf.net/"
|
|
DESCRIPTION = "The psmisc package contains utilities for managing processes on your \
|
|
system: pstree, killall and fuser. The pstree command displays a tree \
|
|
structure of all of the running processes on your system. The killall \
|
|
command sends a specified signal (SIGTERM if nothing is specified) to \
|
|
processes identified by name. The fuser command identifies the PIDs \
|
|
of processes that are using specified files or filesystems."
|
|
SECTION = "base"
|
|
DEPENDS = "ncurses virtual/libintl gettext-native xz-native"
|
|
LICENSE = "GPLv2"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/psmisc/psmisc-${PV}.tar.gz"
|
|
|
|
S = "${WORKDIR}/psmisc-${PV}"
|
|
|
|
inherit autotools gettext
|
|
|
|
# Upstream has a custom autogen.sh which invokes po/update-potfiles as they
|
|
# don't ship a po/POTFILES.in (which is silly). Without that file gettext
|
|
# doesn't believe po/ is a gettext directory and won't generate po/Makefile.
|
|
EXTRA_AUTORECONF_remove = "--exclude=autopoint"
|
|
do_configure_prepend() {
|
|
( cd ${S} && po/update-potfiles )
|
|
}
|
|
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
|
|
PACKAGES =+ "fuser fuser-doc killall killall-doc pstree pstree-doc"
|
|
PACKAGES += "psmisc-extras"
|
|
|
|
FILES_${PN} = ""
|
|
RDEPENDS_${PN} = "fuser killall pstree"
|
|
|
|
FILES_fuser = "${bindir}/fuser.${BPN}"
|
|
FILES_fuser-doc = "${mandir}/man1/fuser*"
|
|
|
|
FILES_killall = "${bindir}/killall.${BPN}"
|
|
FILES_killall-doc = "${mandir}/man1/killall*"
|
|
|
|
FILES_pstree = "${bindir}/pstree"
|
|
FILES_pstree-doc = "${mandir}/man1/pstree*"
|
|
|
|
FILES_psmisc-extras = "${bindir}"
|
|
FILES_psmisc-extras-doc = "${mandir}"
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "90"
|
|
|
|
ALTERNATIVE_killall = "killall"
|
|
|
|
ALTERNATIVE_fuser = "fuser"
|