mirror of
https://git.yoctoproject.org/poky
synced 2026-07-16 03:47:03 +00:00
Ross Burton
5737722432
sudo uses AC_PATH_PROG to find target paths, which means at best potential host-contamination (and reproducible issues) and at worst it thinks sh is at /your/build/path/hosttools/sh. Solve this by explicitly passing the correct paths to configure. (From OE-Core rev: 61650dd8498a093f3bfa93202c9cd2e9a7fb7834) (From OE-Core rev: 6e809474ab686fba6924d8b46fd0b9eab5c66c06) (From OE-Core rev: 232430bdee74bb266ded6ccf2fb3842caad06181) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
2.0 KiB
BlitzBasic
51 lines
2.0 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "https://www.sudo.ws/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-Include-sys-types.h-for-id_t-definition.patch \
|
|
file://CVE-2019-14287-1.patch \
|
|
file://CVE-2019-14287-2.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[md5sum] = "b5c184b13b6b5de32af630af2fd013fd"
|
|
SRC_URI[sha256sum] = "7beb68b94471ef56d8a1036dbcdc09a7b58a949a68ffce48b83f837dd33e2ec0"
|
|
|
|
DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
CACHED_CONFIGUREVARS = " \
|
|
ac_cv_type_rsize_t=no \
|
|
ac_cv_path_MVPROG=${base_bindir}/mv \
|
|
ac_cv_path_BSHELLPROG=${base_bindir}/sh \
|
|
ac_cv_path_SENDMAILPROG=${sbindir}/sendmail \
|
|
ac_cv_path_VIPROG=${base_bindir}/vi \
|
|
"
|
|
|
|
EXTRA_OECONF += " \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${nonarch_libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
--with-vardir=/var/lib/sudo \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
|
|
echo 'auth required pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
|
|
sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
|
|
fi
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the /run directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${nonarch_libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libexecdir}/${BPN}/lib*${SOLIBSDEV} ${libexecdir}/${BPN}/*.la \
|
|
${libexecdir}/lib*${SOLIBSDEV} ${libexecdir}/*.la"
|