mirror of
https://git.yoctoproject.org/poky
synced 2026-07-17 04:07:06 +00:00
Yanfei Xu
79584ffcd3
When you bitbake libsdl2-native and your host had installed fcitx
or ibus, it may cause you bitbake failed in do_compile.
Disable fcitx and ibus check with EXTRA_OECONF in bb file.
-------------snip---------------------
CC build/SDL_sysfilesystem.lo
CC build/SDL_syshaptic.lo
CC build/SDL_systimer.lo
/poky/build/tmp/work/x86_64-linux/libsdl2-native/2.0.10-r0/SDL2-2.0.10/src/core/linux/SDL_fcitx.c:52:5:
error: unknown type name ‘SDL_DBusContext’
SDL_DBusContext *dbus;
^~~~~~~~~~~~~~~
/poky/build/tmp/work/x86_64-linux/libsdl2-native/2.0.10-r0/SDL2-2.0.10/src/core/linux/SDL_fcitx.c:121:8:
error: unknown type name ‘DBusHandlerResult’
static DBusHandlerResult
^~~~~~~~~~~~~~~~~
/poky/build/tmp/work/x86_64-linux/libsdl2-native/2.0.10-r0/SDL2-2.0.10/src/core/linux/SDL_fcitx.c:122:20:
error: unknown type name ‘DBusConnection’;
------------snip----------------------
(From OE-Core rev: f48ab4268746a2780ee0fdc84e5c39afe593ade7)
Signed-off-by: Yanfei Xu <yanfei.xu@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit eb286172e413e9d6449dc13ccec1b78c04481eb5)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
78 lines
3.3 KiB
BlitzBasic
78 lines
3.3 KiB
BlitzBasic
SUMMARY = "Simple DirectMedia Layer"
|
|
DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
|
|
library designed to provide low level access to audio, keyboard, mouse, \
|
|
joystick, 3D hardware via OpenGL, and 2D video framebuffer."
|
|
HOMEPAGE = "http://www.libsdl.org"
|
|
BUGTRACKER = "http://bugzilla.libsdl.org/"
|
|
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://COPYING.txt;md5=504a9454ceb89fd75a2583473b11409e"
|
|
|
|
PROVIDES = "virtual/libsdl2"
|
|
|
|
SRC_URI = "http://www.libsdl.org/release/SDL2-${PV}.tar.gz \
|
|
file://more-gen-depends.patch \
|
|
file://0001-Fixed-bug-4538-validate-image-size-when-loading-BMP-.patch \
|
|
file://0001-configure-check-for-build-dir-when-building-version-.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/SDL2-${PV}"
|
|
|
|
SRC_URI[md5sum] = "5a2114f2a6f348bdab5bf52b994811db"
|
|
SRC_URI[sha256sum] = "b4656c13a1f0d0023ae2f4a9cf08ec92fffb464e0f24238337784159b8b91d57"
|
|
|
|
inherit autotools lib_package binconfig-disabled pkgconfig
|
|
|
|
BINCONFIG = "${bindir}/sdl2-config"
|
|
|
|
CVE_PRODUCT = "simple_directmedia_layer sdl"
|
|
|
|
EXTRA_OECONF = "--disable-oss --disable-esd --disable-arts \
|
|
--disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
|
|
--disable-video-dummy \
|
|
--enable-pthreads \
|
|
--enable-sdl-dlopen \
|
|
--disable-rpath \
|
|
--disable-sndio \
|
|
--disable-fcitx --disable-ibus \
|
|
"
|
|
|
|
# opengl packageconfig factored out to make it easy for distros
|
|
# and BSP layers to pick either (desktop) opengl, gles2, or no GL
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
|
|
|
|
PACKAGECONFIG_class-native = "x11"
|
|
PACKAGECONFIG_class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
|
|
PACKAGECONFIG ??= " \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \
|
|
"
|
|
PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib,"
|
|
PACKAGECONFIG[directfb] = "--enable-video-directfb,--disable-video-directfb,directfb"
|
|
PACKAGECONFIG[gles2] = "--enable-video-opengles,--disable-video-opengles,virtual/libgles2"
|
|
PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack"
|
|
PACKAGECONFIG[kmsdrm] = "--enable-video-kmsdrm,--disable-video-kmsdrm,libdrm virtual/libgbm"
|
|
PACKAGECONFIG[opengl] = "--enable-video-opengl,--disable-video-opengl,virtual/libgl"
|
|
PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio"
|
|
PACKAGECONFIG[tslib] = "--enable-input-tslib,--disable-input-tslib,tslib"
|
|
PACKAGECONFIG[wayland] = "--enable-video-wayland,--disable-video-wayland,wayland-native wayland wayland-protocols libxkbcommon"
|
|
PACKAGECONFIG[x11] = "--enable-video-x11,--disable-video-x11,virtual/libx11 libxext libxrandr libxrender"
|
|
|
|
EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader"
|
|
|
|
do_configure_prepend() {
|
|
# Remove old libtool macros.
|
|
MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4"
|
|
for i in ${MACROS}; do
|
|
rm -f ${S}/acinclude/$i
|
|
done
|
|
export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
|
|
}
|
|
|
|
FILES_${PN}-dev += "${libdir}/cmake"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|