mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:20:16 +00:00
Andre McCurdy
01429e2a64
- Add HOMEPAGE
- Remove ${S} from LIC_FILES_CHKSUM path
- Use tabs consistently to indent do_configure()
- Re-order LIC_FILES_CHKSUM definition to follow OE style guide
(From OE-Core rev: 29f02bca78d7ded464e10d414a111c074d3de242)
Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
(cherry picked from commit 78701c5b873605240226c502de3b940097433596)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
1.8 KiB
BlitzBasic
60 lines
1.8 KiB
BlitzBasic
SUMMARY = "LiSt Open Files tool"
|
|
DESCRIPTION = "Lsof is a Unix-specific diagnostic tool. \
|
|
Its name stands for LiSt Open Files, and it does just that."
|
|
HOMEPAGE = "http://people.freebsd.org/~abe/"
|
|
SECTION = "devel"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://00README;beginline=645;endline=679;md5=964df275d26429ba3b39dbb9f205172a"
|
|
|
|
SRC_URI = "ftp://lsof.itap.purdue.edu/pub/tools/unix/lsof/lsof_${PV}.tar.bz2"
|
|
|
|
SRC_URI[md5sum] = "1b9cd34f3fb86856a125abbf2be3a386"
|
|
SRC_URI[sha256sum] = "81ac2fc5fdc944793baf41a14002b6deb5a29096b387744e28f8c30a360a3718"
|
|
|
|
UPSTREAM_CHECK_URI = "http://www.mirrorservice.org/sites/lsof.itap.purdue.edu/pub/tools/unix/lsof"
|
|
|
|
LOCALSRC = "file://${WORKDIR}/lsof_${PV}/lsof_${PV}_src.tar"
|
|
|
|
S = "${WORKDIR}/lsof_${PV}_src"
|
|
|
|
python do_unpack () {
|
|
# temporarily change S for unpack
|
|
# of lsof_${PV}
|
|
s = d.getVar('S', False)
|
|
d.setVar('S', '${WORKDIR}/lsof_${PV}')
|
|
bb.build.exec_func('base_do_unpack', d)
|
|
# temporarily change SRC_URI for unpack
|
|
# of lsof_${PV}_src
|
|
src_uri = d.getVar('SRC_URI', False)
|
|
d.setVar('SRC_URI', '${LOCALSRC}')
|
|
d.setVar('S', s)
|
|
bb.build.exec_func('base_do_unpack', d)
|
|
d.setVar('SRC_URI', src_uri)
|
|
}
|
|
|
|
export LSOF_INCLUDE = "${STAGING_INCDIR}"
|
|
|
|
do_configure () {
|
|
export LSOF_AR="${AR} cr"
|
|
export LSOF_RANLIB="${RANLIB}"
|
|
if [ "x${GLIBCVERSION}" != "x" ]; then
|
|
LINUX_CLIB=`echo ${GLIBCVERSION} |sed -e 's,\.,,g'`
|
|
LINUX_CLIB="-DGLIBCV=${LINUX_CLIB}"
|
|
export LINUX_CLIB
|
|
fi
|
|
yes | ./Configure linux
|
|
}
|
|
|
|
export I = "${STAGING_INCDIR}"
|
|
export L = "${STAGING_INCDIR}"
|
|
|
|
do_compile () {
|
|
oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS}'
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${sbindir} ${D}${mandir}/man8
|
|
install -m 0755 lsof ${D}${sbindir}/lsof
|
|
install -m 0644 lsof.8 ${D}${mandir}/man8/lsof.8
|
|
}
|