mirror of
https://git.yoctoproject.org/poky
synced 2026-10-23 19:38:18 +00:00
Peter Marko
13d8cd57a7
Per [1] this only affects 2.2.1-alpha. Also [2] markes their versions as not-affected. [1] https://github.com/libevent/libevent/security/advisories/GHSA-3rpf-frgx-xq34 [2] https://security-tracker.debian.org/tracker/CVE-2026-63380 (From OE-Core rev: 7447b6ffb1ef18cecd7d45d2e397018dfa54c78d) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
2.2 KiB
BlitzBasic
60 lines
2.2 KiB
BlitzBasic
SUMMARY = "An asynchronous event notification library"
|
|
DESCRIPTION = "A software library that provides asynchronous event \
|
|
notification. The libevent API provides a mechanism to execute a callback \
|
|
function when a specific event occurs on a file descriptor or after a \
|
|
timeout has been reached. libevent also supports callbacks triggered \
|
|
by signals and regular timeouts"
|
|
HOMEPAGE = "http://libevent.org/"
|
|
BUGTRACKER = "https://github.com/libevent/libevent/issues"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "BSD-3-Clause & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=17f20574c0b154d12236d5fbe964f549"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/release-${PV}-stable/${BP}-stable.tar.gz \
|
|
file://Makefile-missing-test-dir.patch \
|
|
file://run-ptest \
|
|
file://0001-test-regress_dns.c-patch-out-tests-that-require-a-wo.patch \
|
|
file://0002-test-regress.h-Increase-default-timeval-tolerance-50.patch \
|
|
file://0003-test-mark-util-monotonic_prc_fallback-as-retriable.patch \
|
|
file://0004-test-retriable-tests-are-marked-failed-only-when-all-a.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f7e9383b8c0baa81b687e5b5eecc01beefaf1b19b64151d95ed61647fe7a315c"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/release-(?P<pver>.+)-stable"
|
|
|
|
S = "${WORKDIR}/${BPN}-${PV}-stable"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
|
|
inherit autotools github-releases ptest multilib_header
|
|
|
|
# Needed for Debian packaging
|
|
LEAD_SONAME = "libevent-2.1.so"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
PACKAGES_DYNAMIC = "^${PN}-.*$"
|
|
python split_libevent_libs () {
|
|
do_split_packages(d, '${libdir}', r'^libevent_([a-z]*)-.*\.so\..*', '${PN}-%s', '${SUMMARY} (%s)', prepend=True, allow_links=True)
|
|
}
|
|
PACKAGESPLITFUNCS =+ "split_libevent_libs"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_install:append() {
|
|
rm ${D}${bindir}/event_rpcgen.py
|
|
rmdir ${D}${bindir}
|
|
oe_multilib_header event2/event-config.h
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/test
|
|
${B}/libtool --mode=install install ${B}/test/regress ${D}${PTEST_PATH}/test/
|
|
# handle multilib
|
|
sed -i s:@libdir@:${libdir}:g ${D}${PTEST_PATH}/run-ptest
|
|
}
|
|
|
|
CVE_STATUS[CVE-2026-63380] = "fixed-version: only affects 2.2.1-alpha"
|