mirror of
https://git.yoctoproject.org/poky
synced 2026-07-27 19:37:10 +00:00
Richard Purdie
38a9622ba3
Reduce code duplication to a common function in oe.buildcfg. (From OE-Core rev: 0b191a1df4c3722defb09dde0c16b1d9e7fe7ef6) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
66 lines
1.9 KiB
Plaintext
66 lines
1.9 KiB
Plaintext
#
|
|
# Writes build information to target filesystem on /etc/build
|
|
#
|
|
# Copyright (C) 2014 Intel Corporation
|
|
# Author: Alejandro Enedino Hernandez Samaniego <alejandro.hernandez@intel.com>
|
|
#
|
|
# Licensed under the MIT license, see COPYING.MIT for details
|
|
#
|
|
# Usage: add INHERIT += "image-buildinfo" to your conf file
|
|
#
|
|
|
|
# Desired variables to display
|
|
IMAGE_BUILDINFO_VARS ?= "DISTRO DISTRO_VERSION"
|
|
|
|
# Desired location of the output file in the image.
|
|
IMAGE_BUILDINFO_FILE ??= "${sysconfdir}/build"
|
|
|
|
# From buildhistory.bbclass
|
|
def image_buildinfo_outputvars(vars, d):
|
|
vars = vars.split()
|
|
ret = ""
|
|
for var in vars:
|
|
value = d.getVar(var) or ""
|
|
if (d.getVarFlag(var, 'type') == "list"):
|
|
value = oe.utils.squashspaces(value)
|
|
ret += "%s = %s\n" % (var, value)
|
|
return ret.rstrip('\n')
|
|
|
|
# Returns layer revisions along with their respective status
|
|
def get_layer_revs(d):
|
|
revisions = oe.buildcfg.get_layer_revisions(d)
|
|
medadata_revs = ["%-17s = %s:%s%s" % (r[1], r[2], r[3], r[4]) for r in revisions]
|
|
return '\n'.join(medadata_revs)
|
|
|
|
def buildinfo_target(d):
|
|
# Get context
|
|
if d.getVar('BB_WORKERCONTEXT') != '1':
|
|
return ""
|
|
# Single and list variables to be read
|
|
vars = (d.getVar("IMAGE_BUILDINFO_VARS") or "")
|
|
return image_buildinfo_outputvars(vars, d)
|
|
|
|
# Write build information to target filesystem
|
|
python buildinfo () {
|
|
if not d.getVar('IMAGE_BUILDINFO_FILE'):
|
|
return
|
|
with open(d.expand('${IMAGE_ROOTFS}${IMAGE_BUILDINFO_FILE}'), 'w') as build:
|
|
build.writelines((
|
|
'''-----------------------
|
|
Build Configuration: |
|
|
-----------------------
|
|
''',
|
|
buildinfo_target(d),
|
|
'''
|
|
-----------------------
|
|
Layer Revisions: |
|
|
-----------------------
|
|
''',
|
|
get_layer_revs(d),
|
|
'''
|
|
'''
|
|
))
|
|
}
|
|
|
|
IMAGE_PREPROCESS_COMMAND += "buildinfo;"
|