mirror of
https://git.yoctoproject.org/poky
synced 2026-06-16 18:09:56 +00:00
Andre McCurdy
39f6a9e47d
By default, the sqlite3 command-line utility will be statically linked with sqlite3. For OE, dynamic linking is probably more appropriate and can be enabled by configuring with "--disable-static-shell". (From OE-Core rev: 432952090b2faa14437d550f58a00a364d554b2e) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.5 KiB
PHP
54 lines
1.5 KiB
PHP
SUMMARY = "Embeddable SQL database engine"
|
|
HOMEPAGE = "http://www.sqlite.org"
|
|
SECTION = "libs"
|
|
|
|
PE = "3"
|
|
|
|
def sqlite_download_version(d):
|
|
pvsplit = d.getVar('PV', True).split('.')
|
|
if len(pvsplit) < 4:
|
|
pvsplit.append('0')
|
|
return pvsplit[0] + ''.join([part.rjust(2,'0') for part in pvsplit[1:]])
|
|
|
|
SQLITE_PV = "${@sqlite_download_version(d)}"
|
|
|
|
S = "${WORKDIR}/sqlite-autoconf-${SQLITE_PV}"
|
|
|
|
UPSTREAM_CHECK_URI = "http://www.sqlite.org/"
|
|
UPSTREAM_CHECK_REGEX = "releaselog/(?P<pver>(\d+[\.\-_]*)+)\.html"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG_class-native = ""
|
|
|
|
PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline ncurses"
|
|
|
|
EXTRA_OECONF = " \
|
|
--enable-shared \
|
|
--enable-threadsafe \
|
|
--disable-editline \
|
|
--disable-static-shell \
|
|
"
|
|
|
|
# pread() is in POSIX.1-2001 so any reasonable system must surely support it
|
|
BUILD_CFLAGS += "-DUSE_PREAD"
|
|
TARGET_CFLAGS += "-DUSE_PREAD"
|
|
|
|
# Provide column meta-data API
|
|
BUILD_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
|
|
TARGET_CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
|
|
|
|
PACKAGES = "lib${BPN} lib${BPN}-dev lib${BPN}-doc ${PN}-dbg lib${BPN}-staticdev ${PN}"
|
|
|
|
FILES_${PN} = "${bindir}/*"
|
|
FILES_lib${BPN} = "${libdir}/*.so.*"
|
|
FILES_lib${BPN}-dev = "${libdir}/*.la ${libdir}/*.so \
|
|
${libdir}/pkgconfig ${includedir}"
|
|
FILES_lib${BPN}-doc = "${docdir} ${mandir} ${infodir}"
|
|
FILES_lib${BPN}-staticdev = "${libdir}/lib*.a"
|
|
|
|
AUTO_LIBNAME_PKGS = "${MLPREFIX}lib${BPN}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|