mirror of
https://git.yoctoproject.org/poky
synced 2026-05-09 17:39:31 +00:00
Andre McCurdy
691f7e4fa2
- Add glib-2.0-native dependency for target - Add fontconfig-native and freetype-native dependencies for native - Drop unnecessary dependency on zlib for all (From OE-Core rev: 5174b53b33fe6b2f9d71f7c414e2c83bda9f6c94) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.6 KiB
PHP
44 lines
1.6 KiB
PHP
SUMMARY = "Framework for layout and rendering of internationalized text"
|
|
DESCRIPTION = "Pango is a library for laying out and rendering of text, \
|
|
with an emphasis on internationalization. Pango can be used anywhere \
|
|
that text layout is needed, though most of the work on Pango so far has \
|
|
been done in the context of the GTK+ widget toolkit. Pango forms the \
|
|
core of text and font handling for GTK+-2.x."
|
|
HOMEPAGE = "http://www.pango.org/"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPLv2.0+"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native fontconfig freetype virtual/libiconv cairo harfbuzz"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
|
|
PACKAGECONFIG[x11] = "--with-xft,--without-xft,virtual/libx11 libxft"
|
|
|
|
inherit gnomebase gtk-doc ptest-gnome upstream-version-is-even
|
|
|
|
EXTRA_AUTORECONF = ""
|
|
|
|
EXTRA_OECONF = "--disable-introspection \
|
|
--disable-debug \
|
|
"
|
|
|
|
LEAD_SONAME = "libpango-1.0*"
|
|
LIBV = "1.8.0"
|
|
|
|
# This binary needs to be compiled for the host architecture. This isn't pretty!
|
|
do_compile_prepend_class-target () {
|
|
if ${@base_contains('DISTRO_FEATURES', 'ptest', 'true', 'false', d)}; then
|
|
make CC="${BUILD_CC}" CFLAGS="" AM_CPPFLAGS="$(pkg-config-native --cflags glib-2.0)" gen_all_unicode_LDADD="$(pkg-config-native --libs glib-2.0)" -C ${B}/tests gen-all-unicode
|
|
fi
|
|
}
|
|
|
|
FILES_${PN} = "${bindir}/* ${libdir}/libpango*${SOLIBS}"
|
|
FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
|
|
|
|
RDEPENDS_${PN}-ptest += "liberation-fonts"
|
|
|
|
RPROVIDES_${PN} += "pango-modules pango-module-indic-lang \
|
|
pango-module-basic-fc pango-module-arabic-lang"
|
|
|
|
BBCLASSEXTEND = "native"
|