mirror of
https://git.yoctoproject.org/poky
synced 2026-05-09 17:39:31 +00:00
Phil Blundell
7d408d3781
The chkdupexe utility is fairly worthless and drags perl in as a build dependency of the whole util-linux recipe. If anybody actually wants to use this script then we should package it separately, but for the time being let's just delete it. (From OE-Core rev: 19dd830ff8a1b87499b9a51599265dd436214708) Signed-off-by: Phil Blundell <pb@pbcl.net> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.4 KiB
BlitzBasic
43 lines
1.4 KiB
BlitzBasic
MAJOR_VERSION = "2.21"
|
|
PR = "r4"
|
|
require util-linux.inc
|
|
|
|
# note that `lscpu' is under GPLv3+
|
|
LICENSE_${PN}-lscpu = "GPLv3+"
|
|
|
|
SRC_URI += "file://util-linux-ng-replace-siginterrupt.patch \
|
|
file://util-linux-ng-2.16-mount_lock_path.patch \
|
|
file://uclibc-__progname-conflict.patch \
|
|
file://configure-sbindir.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "b75b3cfecb943f74338382fde693c2c3"
|
|
SRC_URI[sha256sum] = "066f9d8e51bfabd809d266edcd54eefba1cdca57725b95c074fd47fe6fba3d30"
|
|
|
|
# Only lscpu part is gplv3; rest of the code is not,
|
|
# so take out the lscpu parts while running non-gplv3 build.
|
|
# The removal of the package should now occur during
|
|
# the build if INCOMPATIBLE_LICENSE is set to GPLv3
|
|
|
|
python () {
|
|
d.setVar("REMOVELSCPU", "no")
|
|
if (d.getVar("INCOMPATIBLE_LICENSE", True) or "").find("GPLv3") != -1:
|
|
# avoid GPLv3
|
|
d.setVar("REMOVELSCPU", "yes")
|
|
src_uri = (d.getVar("SRC_URI", False) or "").split()
|
|
src_uri.append("file://remove-lscpu.patch")
|
|
d.setVar("SRC_URI", " ".join(src_uri))
|
|
}
|
|
|
|
do_remove_lscpu() {
|
|
if [ "x${REMOVELSCPU}" = "xyes" ]; then
|
|
rm -f sys-utils/lscpu.c sys-utils/lscpu.1
|
|
rm -rf tests/ts/lscpu tests/expected/lscpu
|
|
fi
|
|
}
|
|
|
|
addtask remove_lscpu before do_configure after do_patch
|
|
|
|
CACHED_CONFIGUREVARS += "scanf_cv_alloc_modifier=as"
|
|
EXTRA_OECONF_virtclass-native += "--disable-fallocate --disable-use-tty-group"
|