mirror of
https://git.yoctoproject.org/poky
synced 2026-07-27 07:27:12 +00:00
Gary Thomas
8e7f1b444e
When a package is built, some installation scripts must be performed on the target. In the case of a complete image, these scripts are run by a separate step at init time, but only during the first boot (other package install scripts can just be run when the package is installed on the target). This patch lets the distribution (or user) decide when these postponed install scripts should run. The default is normally near the end of init, but there may be times when it's beneficial to run them earlier so the "when" can be overridden. (From OE-Core rev: a46466893407d44dd16ab37ae70e1bee14bdde0a) Signed-off-by: Gary Thomas <gary@mlbassoc.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.5 KiB
BlitzBasic
49 lines
1.5 KiB
BlitzBasic
require opkg.inc
|
|
|
|
PROVIDES += "virtual/update-alternatives"
|
|
RPROVIDES_update-alternatives-cworth += "update-alternatives"
|
|
RCONFLICTS_update-alternatives-cworth = "update-alternatives-dpkg"
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base"
|
|
RDEPENDS_${PN}_virtclass-native = ""
|
|
RDEPENDS_${PN}_virtclass-nativesdk = ""
|
|
PACKAGE_ARCH_update-alternatives-cworth = "all"
|
|
|
|
SRC_URI = "http://opkg.googlecode.com/files/opkg-${PV}.tar.gz \
|
|
file://add_vercmp.patch \
|
|
file://headerfix.patch \
|
|
"
|
|
|
|
PR = "r4"
|
|
|
|
PACKAGES =+ "libopkg${PKGSUFFIX}-dev libopkg${PKGSUFFIX} update-alternatives-cworth${PKGSUFFIX}"
|
|
|
|
FILES_update-alternatives-cworth${PKGSUFFIX} = "${bindir}/update-alternatives"
|
|
FILES_libopkg${PKGSUFFIX}-dev = "${libdir}/*.a ${libdir}/*.la ${libdir}/*.so"
|
|
FILES_libopkg${PKGSUFFIX} = "${libdir}/*.so.* ${localstatedir}/lib/opkg/"
|
|
|
|
# We need to create the lock directory
|
|
do_install_append() {
|
|
install -d ${D}${localstatedir}/lib/opkg
|
|
}
|
|
|
|
pkg_postinst_${PN} () {
|
|
#!/bin/sh
|
|
if [ "x$D" != "x" ]; then
|
|
install -d ${IMAGE_ROOTFS}/${sysconfdir}/rcS.d
|
|
# this happens at S98 where our good 'ole packages script used to run
|
|
echo "#!/bin/sh
|
|
opkg-cl configure
|
|
rm -f /${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}configure
|
|
" > $D${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}configure
|
|
chmod 0755 $D${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}configure
|
|
fi
|
|
|
|
update-alternatives --install ${bindir}/opkg opkg ${bindir}/opkg-cl 100
|
|
}
|
|
|
|
pkg_postrm_${PN} () {
|
|
#!/bin/sh
|
|
update-alternatives --remove opkg ${bindir}/opkg-cl
|
|
}
|
|
|