mirror of
https://git.yoctoproject.org/poky
synced 2026-07-17 04:07:06 +00:00
Wang Mingyu
bf0b19cf8d
0001-mc-replace-perl-w-with-use-warnings.patch
removed since it's included in 4.8.30
Changelog:
==========
- Core
--------
* Support PCRE2 as search engine (via ----with-search-engine=pcre2) (#4450)
* Implement panelization buffers for both file panels (#4370)
- VFS
-------
* tar: support extended headers (including long file names and sparse files) (#1952, #2201)
* extfs helpers: replace "perl -w" with "use warnings" (MidnightCommander/mc#174)
* extfs/patchfs: be more specific in error message (#4485)
- Editor
---------
* Add syntax highlighting:
- Jenkinsfiles (#4469)
- B language (#4470)
* Improve syntax highlighting:
- ECMAScript (MidnightCommander/mc#172)
- ECMAScript in TypeScript (MidnightCommander/mc#172)
- use diff syntax highlighting for git commit messages (COMMIT_EDITMSG) (MidnightCommander/mc#85)
- Misc
--------
* Code cleanup (#4426, #4438)
* Filehighlight:
- recognize vsix files as zip files (MidnightCommander/mc#171)
* Skin updates:
- julia256 (#4441, #4445)
- Fixes
----------
* Usage of 'sed' in build system/makefiles is not portable (#4459, #4466)
* Unportable '$<' in Makefiles (#4460)
* FTBFS if ncurses used without --with-ncurses-includes= configure parameter (#4462)
* Ncurses library is duplicated in MCLIBS (#4463, #4465)
* FTBFS without ext2fs attributes support (#4464)
* Wrong sort order after swapping panels (#4432)
* Incorrect time delimiter in the copy/move progress window (#4437)
* Incorrect redraw of overlapped file panels (#4408)
* Subshell/Command line prompt is empty/missing (#3121)
* Find file: relative ignore directory is applied to the start search directory (#4235)
* Diff viewer: options are not applied on second run (#4486)
* mc.ext.ini: 'Edit' command from 'Default' section is ignored (#4434)
* mc.ext.ini: .md files are not recognized as Markdown ones by extension (#4444)
* mcedit: off-by-one error in paragraph formatting (#4446)
* ftp: incomplete file listing: block and character devices, pipes, sockets are missed (#4472)
* Various typos in the source code (MidnightCommander/mc#177, MidnightCommander/mc#178)
(From OE-Core rev: 9ba1f7042de6e430c687970657173740eec9ea7b)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
3.0 KiB
BlitzBasic
58 lines
3.0 KiB
BlitzBasic
SUMMARY = "Midnight Commander is an ncurses based file manager"
|
|
HOMEPAGE = "http://www.midnight-commander.org/"
|
|
DESCRIPTION = "GNU Midnight Commander is a visual file manager, licensed under GNU General Public License and therefore qualifies as Free Software. It's a feature rich full-screen text mode application that allows you to copy, move and delete files and whole directory trees, search for files and run commands in the subshell. Internal viewer and editor are included."
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=270bbafe360e73f9840bd7981621f9c2"
|
|
SECTION = "console/utils"
|
|
DEPENDS = "ncurses glib-2.0 util-linux file-replacement-native"
|
|
RDEPENDS:${PN} = "ncurses-terminfo-base"
|
|
RRECOMMENDS:${PN} = "ncurses-terminfo"
|
|
|
|
SRC_URI = "http://www.midnight-commander.org/downloads/${BPN}-${PV}.tar.bz2 \
|
|
file://nomandate.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "38171f22f889e3030ec9055463d3ecd7843984ab24e6497d8294d1c441a7ddb4"
|
|
|
|
inherit autotools gettext pkgconfig
|
|
|
|
#
|
|
# Both Samba (smb) and sftp require package delivered from meta-openembedded
|
|
#
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[sftp] = "--enable-vfs-sftp,--disable-vfs-sftp,libssh2,"
|
|
|
|
# enable NCURSES_WIDECHAR=1 only if ENABLE_WIDEC has not been explicitly disabled (e.g. by the distro config).
|
|
# When compiling against the ncurses library, NCURSES_WIDECHAR needs to explicitly set to 0 in this case.
|
|
CFLAGS:append:libc-musl = "${@' -DNCURSES_WIDECHAR=1' if bb.utils.to_boolean((d.getVar('ENABLE_WIDEC') or 'True')) else ' -DNCURSES_WIDECHAR=0'}"
|
|
EXTRA_OECONF = "--with-screen=ncurses --without-gpm-mouse --without-x --disable-configure-args"
|
|
EXTRANATIVEPATH += "file-native"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_PERL='/usr/bin/env perl'"
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_PERL_FOR_BUILD='/usr/bin/env perl'"
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_PYTHON='/usr/bin/env python'"
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_GREP='/usr/bin/env grep'"
|
|
CACHED_CONFIGUREVARS += "mc_cv_have_zipinfo=yes"
|
|
|
|
do_install:append () {
|
|
sed -i -e '1s,#!.*perl,#!${bindir}/env perl,' ${D}${libexecdir}/mc/extfs.d/*
|
|
|
|
rm ${D}${libexecdir}/mc/extfs.d/s3+ ${D}${libexecdir}/mc/extfs.d/uc1541
|
|
}
|
|
|
|
PACKAGES =+ "${BPN}-helpers-perl ${BPN}-helpers ${BPN}-fish"
|
|
|
|
SUMMARY:${BPN}-helpers-perl = "Midnight Commander Perl-based helper scripts"
|
|
FILES:${BPN}-helpers-perl = "${libexecdir}/mc/extfs.d/a+ ${libexecdir}/mc/extfs.d/apt+ \
|
|
${libexecdir}/mc/extfs.d/deb ${libexecdir}/mc/extfs.d/deba \
|
|
${libexecdir}/mc/extfs.d/debd ${libexecdir}/mc/extfs.d/dpkg+ \
|
|
${libexecdir}/mc/extfs.d/mailfs ${libexecdir}/mc/extfs.d/patchfs \
|
|
${libexecdir}/mc/extfs.d/rpms+ ${libexecdir}/mc/extfs.d/ulib \
|
|
${libexecdir}/mc/extfs.d/uzip"
|
|
RDEPENDS:${BPN}-helpers-perl = "perl"
|
|
|
|
SUMMARY:${BPN}-helpers = "Midnight Commander shell helper scripts"
|
|
FILES:${BPN}-helpers = "${libexecdir}/mc/extfs.d/* ${libexecdir}/mc/ext.d/*"
|
|
|
|
SUMMARY:${BPN}-fish = "Midnight Commander Fish scripts"
|
|
FILES:${BPN}-fish = "${libexecdir}/mc/fish"
|