mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 00:39:46 +00:00
Bruce Ashfield
f98ea33f63
To support builds against v5.13+ kernels, bumping the devupstream to 2.13 and the 2.13-rc series. Along with the SRCREV update, a port of the existing CONFIG_TRACEPOINTS patch from the main Makefile to src/Kbuild is done. The LICENSE file was part of commit [Cleanup: Move headers from toplevel to include/lttng/], so we adjust the checksum to the new fie contents. (From OE-Core rev: 18bf7b0eafc5331b0b33c0ae777374e24df741b8) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
2.2 KiB
BlitzBasic
50 lines
2.2 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPLv2.1 & GPLv2 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3f882d431dc0f32f1f44c0707aa41128"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://Makefile-Do-not-fail-if-CONFIG_TRACEPOINTS-is-not-en.patch \
|
|
file://0001-Fix-memory-leaks-on-event-destroy.patch \
|
|
file://0002-Fix-filter-interpreter-early-exits-on-uninitialized-.patch \
|
|
file://0003-fix-mm-tracing-record-slab-name-for-kmem_cache_free-.patch \
|
|
file://0004-Fix-kretprobe-null-ptr-deref-on-session-destroy.patch \
|
|
file://0005-fix-block-add-a-disk_uevent-helper-v5.12.patch \
|
|
file://0006-fix-backport-block-add-a-disk_uevent-helper-v5.12.patch \
|
|
file://0007-fix-mm-tracing-kfree-event-name-mismatching-with-pro.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "c4d1a1b42c728e37b6b7947ae16563a011c4b297311aa04d56f9a1791fb5a30a"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
do_install_append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
}
|
|
|
|
python do_package_prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
LIC_FILES_CHKSUM_class-devupstream = "file://LICENSE;md5=0464cff101a009c403cd2ed65d01d4c4"
|
|
DEFAULT_PREFERENCE_class-devupstream = "-1"
|
|
SRC_URI_class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13 \
|
|
file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch \
|
|
"
|
|
|
|
SRCREV_class-devupstream = "f982b51a98a29cb4aaf607cb9bbf2b509d8e6933"
|
|
PV_class-devupstream = "2.13.0-rc2+git${SRCPV}"
|
|
S_class-devupstream = "${WORKDIR}/git"
|
|
SRCREV_FORMAT ?= "lttng_git"
|