DESCRIPTION = "ALPM library"
HOMEPAGE = "https://gitlab.archlinux.org/pacman/pacman"
SECTION = "libs"
LICENSE = "GPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"

FILESEXTRAPATHS:prepend := "${THISDIR}/files:"

SRC_URI = "git://gitlab.archlinux.org/pacman/pacman.git;protocol=https;nobranch=1"
SRCREV = "5537881b2525a4f114fcf10b00413b4575a74968"
SRC_URI += " \
             file://0001-disable-po.patch \
           "
S = "${WORKDIR}/git"

DEPENDS = "libtool-native autoconf-archive-native libarchive openssl bash"
RDEPENDS:${PN} += "bash perl"

EXTRA_OECONF = ' \
                 --disable-doc \
                 --disable-nls \
                 --with-crypto=openssl \
                 CC="${CC}" \
               '

do_configure:prepend() {
	install -d ${S}/build-aux
	touch ${S}/build-aux/config.rpath
}

do_install:append() {
	rm -rf ${D}/usr/share
	rm -rf ${D}/usr/bin/repo-add
	rm -rf ${D}/usr/bin/pacman-key
	rm -rf ${D}/usr/bin/pacman-db-upgrade
	rm -rf ${D}/usr/bin/makepkg

	install -d ${D}/usr/include
	install -m 0644 ${S}/lib/libalpm/*.h ${D}/usr/include/
}

inherit autotools pkgconfig gettext

FILES:${PN}-dev += " \
                     /usr/include/*.h \
                   "