# Copyright (C) 2022 Vincent BENOIT <vincent.benoit@benserv.fr>
# Release under the MIT license (see COPYING.MIT for the terms)

HOMEPAGE = "https://git.nas.benserv.fr/vincent/KineIntercom.git"
SUMMARY = "KineIntercom Process"
MAINTAINER = "Vincent BENOIT <vincent.benoit@benserv.fr>"
LIC_FILES_CHKSUM = "file://LICENSE;md5=7dda4e90ded66ab88b86f76169f28663"
LICENSE = "MIT"

FILESEXTRAPATHS:prepend := "${THISDIR}/files:"

PV = "1.0.0"
SRC_URI = "git://git.nas.benserv.fr/vincent/KineIntercom.git;protocol=https;branch=master"

SRCREV = "3a07adf319a19e1f322bc86eba4decba5bb9d0eb"

S = "${WORKDIR}/git"

DEPENDS = "python3-setuptools-scm-native kine-users"
RDEPENDS:${PN} = "python3-apscheduler python3-jsonschema python3-pyserial rpi-gpio kine-users rsyslog"

inherit setuptools3 systemd

SRC_URI += " file://database_origin.json \
             file://db.json.schema \
             file://kineintercom.service"

FILES:${PN} += " ${datadir}/kineintercom/database_origin.json \
                 ${datadir}/kineintercom/db.json.schema \
                 ${systemd_unitdir}/system/kineintercom.service"

SYSTEMD_AUTO_ENABLE = "enable"
SYSTEMD_SERVICE:${PN} = "kineintercom.service"

do_install:append() {
	install -d ${D}${datadir}/kineintercom
	install -m 0660 ${WORKDIR}/database_origin.json ${D}${datadir}/kineintercom/
	install -m 0660 ${WORKDIR}/db.json.schema ${D}${datadir}/kineintercom/
	chown -R root:pi ${D}${datadir}/kineintercom
	install -d ${D}${sysconfdir}/kineintercom
	chown -R root:pi ${D}${sysconfdir}/kineintercom
	chmod 770 ${D}${sysconfdir}/kineintercom

	install -d ${D}${systemd_unitdir}/system/
	install -m 0644 ${WORKDIR}/kineintercom.service ${D}${systemd_unitdir}/system/

	install -d ${D}/var/log/kineintercom
	chown -R pi:pi ${D}/var/log/kineintercom
}