ttf-mplus: update to latest revision

The original sourceforge project page doesn't exist anymore along
with the original download location. The project switched to github.

From the github history it is not possible to determine when did it
switch license to OFL (sourceforge history was not imported),
it used this license from the initial commit.

Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-oe/recipes-graphics/ttf-fonts/ttf-mplus_027.bb

@@ -1,25 +0,0 @@
-require ttf.inc
-
-SUMMARY = "MPlus font - TTF Edition"
-HOMEPAGE = "http://dejavu.sourceforge.net/wiki/"
-LICENSE = "${BPN}"
-LIC_FILES_CHKSUM = "file://LICENSE_E;md5=ac161e96eda00db9a3aec7870b5d9658 \
-                    file://LICENSE_J;md5=a120ca8d7c8e4a475d5277c9aeb95221 \
-"
-SRC_URI = "http://downloads.sourceforge.jp/mplus-fonts/6650/mplus-TESTFLIGHT-${PV}.tar.gz"
-S = "${UNPACKDIR}/mplus-TESTFLIGHT-${PV}"
-
-PACKAGESPLITFUNCS:prepend = "split_ttf_mplus_packages "
-
-python split_ttf_mplus_packages() {
-    plugindir = d.expand('${datadir}/fonts/ttf-mplus/')
-    packages = do_split_packages(d, plugindir, r'^(.*)\.ttf$', 'ttf-%s', 'TTF Font %s')
-    d.setVar('FONT_PACKAGES', ' '.join(packages))
-}
-
-do_install() {
-    install -d ${D}${datadir}/fonts/ttf-mplus
-    install -m 0644 *.ttf ${D}${datadir}/fonts/ttf-mplus/
-}
-
-SRC_URI[sha256sum] = "a20b9b9b03c2a6fb1e2137d29e8a6ce06406ba1e008906ea3c474dc048dc06a6"

meta-oe/recipes-graphics/ttf-fonts/ttf-mplus_git.bb

@@ -0,0 +1,25 @@
+require ttf.inc
+
+SUMMARY = "MPlus font - TTF Edition"
+HOMEPAGE = "https://mplusfonts.github.io/"
+LICENSE = "OFL-1.1"
+LIC_FILES_CHKSUM = "file://OFL.txt;md5=ee870a4a7cee012360178b2f8bccb725"
+
+SRC_URI = "git://github.com/coz-m/MPLUS_FONTS.git;protocol=https;branch=master"
+SRCREV = "80ac404d0c80442781b6f4c6119a8c9e71770806"
+
+PACKAGESPLITFUNCS:prepend = "split_ttf_mplus_packages "
+
+python split_ttf_mplus_packages() {
+    plugindir = d.expand('${datadir}/fonts/ttf-mplus/')
+    packages = do_split_packages(d, plugindir, r'^(.*)\.ttf$', 'ttf-%s', 'TTF Font %s')
+    d.setVar('FONT_PACKAGES', ' '.join(packages))
+}
+
+do_install() {
+    install -d ${D}${datadir}/fonts/ttf-mplus
+    cd fonts/ttf
+    for f in *.ttf; do
+        install -m 0644 $f ${D}${datadir}/fonts/ttf-mplus/"$(echo "$f" | tr '[]' '_')"
+    done
+}