libcanberra: upgrade and refresh packaging

Update to 0.29 (latest, 0.30, needs GStreamer 1.0) and refresh the package based
on the different recipes in oe-core and meta-oe.

Explicitly depend on GTK+ 2 and GTK+ 3, but split those dependencies into
different packages.

Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

meta-oe/recipes-devtools/libcanberra/libcanberra/libcanberra-increase-buffer-size.patch

@@ -1,13 +0,0 @@
-Index: libcanberra-0.14/src/alsa.c
-===================================================================
---- libcanberra-0.14.orig/src/alsa.c
-+++ libcanberra-0.14/src/alsa.c
-@@ -272,7 +272,7 @@
-     return translate_error(ret);
- }
- 
--#define BUFSIZE (16*1024)
-+#define BUFSIZE (128*1024)
- 
- static void* thread_func(void *userdata) {
-     struct outstanding *out = userdata;

meta-oe/recipes-devtools/libcanberra/libcanberra_0.26.bb

@@ -1,63 +0,0 @@
-DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name \
-Specifications, for generating event sounds on free desktops."
-LICENSE = "LGPLv2.1+"
-LIC_FILES_CHKSUM = "file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1"
-DEPENDS = "alsa-lib gstreamer gtk+ libtool libvorbis gconf"
-SECTION = "libs/multimedia"
-AUTHOR = "Lennart Poettering"
-HOMEPAGE = "http://0pointer.de/lennart/projects/libcanberra"
-PR = "r2"
-
-inherit autotools vala
-
-SRC_URI = "http://0pointer.de/lennart/projects/libcanberra/libcanberra-${PV}.tar.gz \
-           file://libcanberra-increase-buffer-size.patch"
-
-SRC_URI[md5sum] = "ee2c66ada7c851a4e7b6eb1682285a24"
-SRC_URI[sha256sum] = "4b5d8d2c2835133620adbc53745dd107b6e58b9a2963059e8f457143fee00982"
-
-EXTRA_OECONF = "\
-  --enable-alsa \
-  --enable-gstreamer \
-  --enable-gtk \
-  --enable-multi \
-  --enable-null \
-  --disable-oss \
-  --disable-pulse \
-  --disable-tdb \
-"
-# enable pulse again when pulseaudio >= 0.9.11 is the default in OE
-
-python populate_packages_prepend() {
-    plugindir = d.expand('${libdir}/${P}/')
-    do_split_packages(d, plugindir, '^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' )
-}
-
-PACKAGES =+ "${PN}-gtk"
-
-PACKAGES_DYNAMIC += "^libcanberra-.*"
-
-FILES_${PN}-gtk = "\
-  ${sysconfdir}/gconf \
-  ${bindir}/* \
-  ${libdir}/libcanberra-gtk.so.* \
-  ${libdir}/gtk-2.0/modules/* \
-  ${libdir}/gtk-3.0/modules/* \
-  ${datadir}/gnome \
-  ${datadir}/gdm \
-"
-
-# /usr/lib/gtk-3.0/modules/libcanberra-gtk-module.so > /usr/lib/gtk-3.0/modules/libcanberra-gtk3-module.so
-INSANE_SKIP_${PN}-gtk = "dev-so"
-
-FILES_${PN}-dev += "\
-  ${libdir}/gtk-2.0/modules/*.la \
-  ${libdir}/gtk-3.0/modules/*.la \
-  ${libdir}/${P}/*.la \
-"
-
-FILES_${PN}-dbg += "\
-  ${libdir}/gtk-2.0/modules/.debug \
-  ${libdir}/gtk-3.0/modules/.debug \
-  ${libdir}/${P}/.debug \
-"

meta-oe/recipes-support/libcanberra/libcanberra_0.29.bb

@@ -0,0 +1,55 @@
+SUMMARY = "Implementation of XDG Sound Theme and Name Specifications"
+DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name Specifications, for generating event sounds on free desktops."
+LICENSE = "LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
+                    file://src/canberra.h;beginline=7;endline=24;md5=c616c687cf8da540a14f917e0d23ab03"
+
+DEPENDS = "alsa-lib gstreamer gtk+ gtk+3 libtool libvorbis pulseaudio"
+PR = "r0"
+
+inherit autotools
+
+SRC_URI = "http://0pointer.de/lennart/projects/${BPN}/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "2594093a5d61047bd9cc87e955f86df8"
+SRC_URI[sha256sum] = "127a5ef07805856d63758e5180ebfb241d1f80094fd301c287591a15b8cfcd72"
+
+EXTRA_OECONF = "\
+  --enable-null \
+  --enable-alsa \
+  --enable-gstreamer \
+  --enable-pulse \
+  --disable-oss \
+  --enable-gtk \
+  --enable-gtk3 \
+  --disable-tdb \
+  --disable-lynx \
+"
+
+python populate_packages_prepend() {
+    plugindir = d.expand('${libdir}/${P}/')
+    do_split_packages(d, plugindir, '^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' )
+    do_split_packages(d, plugindir, '^libcanberra-(.*)\.la$', 'libcanberra-%s', '%s support library', extra_depends='' )
+}
+
+PACKAGES =+ "${PN}-gnome ${PN}-gtk2 ${PN}-gtk3 ${PN}-systemd"
+
+FILES_${PN} = "${bindir}/ ${libdir}/${BPN}.so.*"
+
+FILES_${PN}-dev += "${datadir}/vala/vapi"
+
+FILES_${PN}-dbg += "${libdir}/${P}/.debug ${libdir}/gtk-*/modules/.debug"
+
+FILES_${PN}-gtk2 = "${libdir}/${BPN}-gtk.so.* \
+                    ${libdir}/gtk-2.0/modules/*.la \
+                    ${libdir}/gtk-2.0/modules/*.so"
+
+# -gtk3 ships a symlink to a .so
+INSANE_SKIP_${PN}-gtk3 = "dev-so"
+FILES_${PN}-gtk3 = "${libdir}/${BPN}-gtk3.so.* \
+                    ${libdir}/gtk-3.0/modules/*.la \
+                    ${libdir}/gtk-3.0/modules/*.so"
+
+FILES_${PN}-gnome = "${libdir}/gnome-settings-daemon-3.0/ \
+                     ${datadir}/gdm/ ${datadir}/gnome/"
+
+FILES_${PN}-systemd = "${base_libdir}/systemd/system/*.service"