mirrors/meta-openembedded
1
0
Fork 0
mirror of https://github.com/openembedded/meta-openembedded.git synced 2026-04-20 11:38:34 +00:00
Code Issues Projects Releases Wiki Activity

vboxguestdrivers: Add recipe for vbox 5.x

Browse Source 
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
This commit is contained in:
Khem Raj
2016-08-22 10:27:16 -07:00
committed by Martin Jansa
parent fef7b1feb7
commit 2892bd69fa
2 changed files with 69 additions and 2 deletions
Download Patch File Download Diff File Expand all files Collapse all files

6
meta-oe/recipes-support/vboxguestdrivers/vboxguestdrivers/Makefile.utils
View File

@@ -10,8 +10,10 @@
##
## -----------------------------------------------------------------------
INCLUDES = -I. -I../vboxsf
CFLAGS = ${INCLUDES}
INCLUDES = -I. -I../vboxsf -I../vboxsf/include
MOD_DEFS = -DRT_OS_LINUX -DIN_RING0 -DIN_RT_R0 \
-DIN_SUP_R0 -DVBOX -DVBOX_WITH_HGCM -DIN_MODULE -DIN_GUEST_R0
CFLAGS = ${INCLUDES} ${MOD_DEFS}
LDFLAGS =
SRCS = mount.vboxsf.c \

65
meta-oe/recipes-support/vboxguestdrivers/vboxguestdrivers_5.1.4.bb Normal file
View File

@@ -0,0 +1,65 @@
SUMMARY = "VirtualBox Linux Guest Drivers"
SECTION = "core"
LICENSE = "GPL-2.0"
LIC_FILES_CHKSUM = "file://${WORKDIR}/${VBOX_NAME}/COPYING;md5=e197d5641bb35b29d46ca8c4bf7f2660"
DEPENDS = "virtual/kernel"
inherit module kernel-module-split
COMPATIBLE_MACHINE = "(qemux86|qemux86-64)"
VBOX_NAME = "VirtualBox-${PV}"
SRC_URI = "http://download.virtualbox.org/virtualbox/${PV}/${VBOX_NAME}.tar.bz2 \
file://Makefile.utils \
"
SRC_URI[md5sum] = "e25a6a1f3c113c373dc0433f9c2526f3"
SRC_URI[sha256sum] = "b9a14a7771059c55c44b97f8d4eef9bea84544f3e215e0caa563bc35e2f16aaf"
S = "${WORKDIR}/vbox_module"
export BUILD_TARGET_ARCH="${ARCH}"
export BUILD_TARGET_ARCH_x86-64="amd64"
export KERN_DIR="${STAGING_KERNEL_DIR}"
addtask export_sources before do_patch after do_unpack
do_export_sources() {
mkdir -p "${S}"
${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/export_modules ${T}/vbox_modules.tar.gz
tar -C "${S}" -xzf ${T}/vbox_modules.tar.gz
# add a mount utility to use shared folder from VBox Addition Source Code
mkdir -p "${S}/utils"
install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/mount.vboxsf.c ${S}/utils
install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/vbsfmount.c ${S}/utils
install ${S}/../Makefile.utils ${S}/utils/Makefile
}
# compile and install mount utility
do_compile_append() {
oe_runmake 'LD=${CC}' 'LDFLAGS=${LDFLAGS}' -C ${S}/utils
}
module_do_install() {
MODULE_DIR=${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/kernel/misc
install -d $MODULE_DIR
install -m 644 vboxguest.ko $MODULE_DIR
install -m 644 vboxsf.ko $MODULE_DIR
install -m 644 vboxvideo.ko $MODULE_DIR
}
do_install_append() {
install -d ${D}${base_sbindir}
install -m 755 ${S}/utils/mount.vboxsf ${D}${base_sbindir}
}
PACKAGES += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
RRECOMMENDS_${PN} += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
FILES_${PN} = "${base_sbindir}"
# autoload if installed
KERNEL_MODULE_AUTOLOAD += "vboxguest vboxsf vboxvideo"