libfaketime: add recipe

This commit adds the libfaketime library recipe, which provides time
manipulation capabilities for testing and debugging purposes. libfaketime allows
developers to modify the system time reported to applications, aiding in scenarios
where accurate time emulation is required.

I deleted the extra flags altogether as they seem to be only necessary
for old versions of this project (0.9.6).

CC: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Tymoteusz Burak <tymoteusz.burak@3mdeb.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-oe/recipes-test/libfaketime/libfaketime_0.9.10.bb

@@ -0,0 +1,30 @@
+DESCRIPTION = "A library for faking the system time in user-space programs"
+SECTION = "libs"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRCREV = "d475b925943ad404c6c728ac868dc73949e7281c"
+SRC_URI = "\
+    git://git@github.com/wolfcw/libfaketime.git;branch=master;protocol=https \
+    "
+
+S = "${WORKDIR}/git"
+
+do_configure[noexec] = "1"
+do_compile () {
+    oe_runmake
+}
+do_install () {
+    install -d ${D}${libdir}/faketime
+    oe_libinstall -C src libfaketime ${D}${libdir}/faketime
+    install -d ${D}${bindir}
+    install -m 0755 src/faketime ${D}${bindir}
+}
+
+PACKAGES =+ "lib${PN}"
+
+FILES:${PN} = "${bindir}/faketime"
+FILES:lib${PN} = "${libdir}/faketime/*"
+
+INSANE_SKIP:${PN} += "dev-so"
+INSANE_SKIP:lib${PN} += "dev-so"