mirrors/meta-openembedded
1
0
Fork 0
mirror of https://github.com/openembedded/meta-openembedded.git synced 2026-06-06 15:20:12 +00:00
Code Issues Projects Releases Wiki Activity

fbida 2.09: cleanups and use PACKAGECONFIG

Browse Source 
There are now 3 packageconfig variables: gif, png, tiff.

Changes:
- rename recipe to _git (match SRCREV)
- fix missing $ for STAGING_INCDIR (jpeg version detection)
- add DESCRIPTION
- no more QA warnings
Use this to reveal:
sed -i -e '/^verbose/s/no/yes/' ${S}/mk/Autoconf.mk

Signed-off-by: Matthieu Crapet <Matthieu.Crapet@ingenico.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
This commit is contained in:
Matthieu CRAPET
2014-02-28 15:11:04 +01:00
committed by Martin Jansa
parent 0d3445e00a
commit 50f7a7c966
2 changed files with 52 additions and 27 deletions
Download Patch File Download Diff File Expand all files Collapse all files
meta-oe/recipes-graphics/fbida/fbida_2.09.bb
-27
View File
@@ -1,27 +0,0 @@
HOMEPAGE = "http://linux.bytesex.org/fbida/"
SUMMARY = "frame buffer image and doc viewer tools"
AUTHOR = "Gerd Hoffmann"
SECTION = "utils"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
DEPENDS = "virtual/libiconv libpng jpeg fontconfig freetype libexif curl libungif tiff"
SRC_URI = "git://git.kraxel.org/fbida"
SRCREV = "cb0ce5fa5f42bfaea4f8f326bcd8914dd14e782d"
S = "${WORKDIR}/git"
EXTRA_OEMAKE = "STRIP="
do_compile() {
sed -i -e 's: cpp: ${TARGET_PREFIX}cpp -I{STAGING_INCDIR}:g' GNUmakefile
oe_runmake
}
do_install() {
oe_runmake 'DESTDIR=${D}' install
}
RDEPENDS_${PN} = "ttf-dejavu-sans-mono"
meta-oe/recipes-graphics/fbida/fbida_git.bb
+52
View File
@@ -0,0 +1,52 @@
SUMMARY = "Framebuffer image and doc viewer tools"
DESCRIPTION = "The fbida project contains a few applications for viewing and editing images, \
with the main focus being photos."
HOMEPAGE = "http://linux.bytesex.org/fbida/"
AUTHOR = "Gerd Hoffmann"
SECTION = "utils"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
DEPENDS = "virtual/libiconv jpeg fontconfig freetype libexif curl"
SRC_URI = "git://git.kraxel.org/fbida"
SRCREV = "cb0ce5fa5f42bfaea4f8f326bcd8914dd14e782d"
PV = "2.09+git${SRCPV}"
S = "${WORKDIR}/git"
EXTRA_OEMAKE = "STRIP="
PACKAGECONFIG ??= "gif png"
PACKAGECONFIG[gif] = ",,libungif"
PACKAGECONFIG[png] = ",,libpng"
PACKAGECONFIG[tiff] = ",,tiff"
do_compile() {
sed -i -e 's:/sbin/ldconfig:echo x:' ${S}/mk/Autoconf.mk
sed -i -e 's: cpp: ${TARGET_PREFIX}cpp -I${STAGING_INCDIR}:' ${S}/GNUmakefile
if [ -z "${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}" ]; then
sed -i -e '/^HAVE_MOTIF/s/:=.*$/:= no/' ${S}/GNUmakefile
fi
# Be sure to respect preferences (force to "no")
# Also avoid issues when ${BUILD_ARCH} == ${HOST_ARCH}
if [ -z "${@base_contains('PACKAGECONFIG', 'gif', 'gif', '', d)}" ]; then
sed -i -e '/^HAVE_LIBUNGIF/s/:=.*$/:= no/' ${S}/GNUmakefile
fi
if [ -z "${@base_contains('PACKAGECONFIG', 'png', 'png', '', d)}" ]; then
sed -i -e '/^HAVE_LIBPNG/s/:=.*$/:= no/' ${S}/GNUmakefile
fi
if [ -z "${@base_contains('PACKAGECONFIG', 'tiff', 'tiff', '', d)}" ]; then
sed -i -e '/^HAVE_LIBTIFF/s/:=.*$/:= no/' ${S}/GNUmakefile
fi
oe_runmake
}
do_install() {
oe_runmake 'DESTDIR=${D}' install
}
RDEPENDS_${PN} = "ttf-dejavu-sans-mono"