lvm2: make it more explicit that readline support is disabled by default

Any PACKAGECONFIG default assigned with ??= is lost by subsequent
assignments with +=, therefore lvm2 is currently building with the
readline PACKAGECONFIG disabled. Make that explicitly clear in the
recipe. Also minor formatting updates, to align with style guide.

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

meta-oe/recipes-support/lvm2/lvm2.inc

@@ -5,7 +5,6 @@ LICENSE = "GPLv2 & LGPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
                     file://COPYING.LIB;md5=fbc093901857fcd118f065f900982c24"
 
-S = "${WORKDIR}/LVM2.${PV}"
 SRC_URI = "ftp://sources.redhat.com/pub/lvm2/old/LVM2.${PV}.tgz \
            file://lvm.conf \
            file://0001-implement-libc-specific-_reopen_stream.patch \
@@ -14,8 +13,14 @@ SRC_URI = "ftp://sources.redhat.com/pub/lvm2/old/LVM2.${PV}.tgz \
            file://0004-include-fcntl.h-for-O_-defines-and-fcntl-signature.patch \
            "
 
-PACKAGECONFIG ??= "readline"
+S = "${WORKDIR}/LVM2.${PV}"
+
+inherit autotools-brokensep pkgconfig systemd
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'selinux', 'selinux', '', d)}"
+
 PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline"
+PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux"
 
 # Unset user/group to unbreak install.
 EXTRA_OECONF = "--with-user= \
@@ -34,12 +39,6 @@ EXTRA_OECONF = "--with-user= \
                 --with-systemdsystemunitdir=${systemd_system_unitdir} \
 "
 
-PACKAGECONFIG += "${@base_contains('DISTRO_FEATURES', 'selinux', 'selinux', '', d)}"
-
-PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
-
-inherit autotools-brokensep pkgconfig systemd
-
 do_install_append() {
     # Install machine specific configuration file
     install -m 0644 ${WORKDIR}/lvm.conf ${D}${sysconfdir}/lvm/lvm.conf