meta-efl: evas-generic-loaders: add new recipes to cope with missing SVG support in newer evas

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

meta-efl/conf/distro/include/efl-from-svn-recipes.inc

@@ -18,6 +18,7 @@ PREFERRED_VERSION_eina-native ?= "${EFL_PREFERRED_VERSION}"
 PREFERRED_VERSION_embryo ?= "${EFL_PREFERRED_VERSION}"
 PREFERRED_VERSION_embryo-native ?= "${EFL_PREFERRED_VERSION}"
 PREFERRED_VERSION_evas ?= "${EFL_PREFERRED_VERSION}"
+PREFERRED_VERSION_evas-generic-loaders ?= "1.2.0+svn%"
 PREFERRED_VERSION_evas-native ?= "${EFL_PREFERRED_VERSION}"
 PREFERRED_VERSION_expedite ?= "${EFL_PREFERRED_VERSION}"
 PREFERRED_VERSION_expedite-native ?= "${EFL_PREFERRED_VERSION}"

meta-efl/recipes-efl/efl/evas-generic-loaders.inc

@@ -0,0 +1,33 @@
+DESCRIPTION = "Evas generic loaders"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=06568fc31423f3c8ad84f375e061c342"
+DEPENDS = "eina poppler librsvg cairo"
+
+inherit efl
+
+INC_PR = "r0"
+
+SRCNAME = "evas_generic_loaders"
+
+EXTRA_OECONF = " \
+  --enable-poppler \
+  --enable-svg \
+  --disable-gstreamer \
+  --disable-libraw \
+  --disable-spectre \
+"
+
+python populate_packages_prepend () {
+    bb.note( "splitting packages for evas generic loaders" )
+    basedir = bb.data.expand( '${libdir}/evas/utils', d )
+
+    do_split_packages(d, basedir, '^evas_image_loader\.(.*)$',
+    output_pattern = "evas-generic-loader-%s",
+    description = 'Evas generic loaders - module %s',
+    allow_dirs=True, recursive=False, extra_depends="" )
+}
+
+FILES_evas-generic-loader-xcf += "${libdir}/evas/utils/*.xcf.gz"
+FILES_${PN}-dbg += "${libdir}/evas/utils/.debug"
+
+PACKAGES_DYNAMIC = "evas-generic-loader-*"

meta-efl/recipes-efl/efl/evas-generic-loaders_1.2.0.bb

@@ -0,0 +1,10 @@
+require ${BPN}.inc
+
+PR = "${INC_PR}.0"
+
+SRC_URI = "\
+  ${E_MIRROR}/${SRCNAME}-${PV}.tar.gz \
+"
+
+SRC_URI[md5sum] = "340a8c2f42c82ecd10f0204cdb291a70"
+SRC_URI[sha256sum] = "9a3aad43269f34513765b04ed3e8db5a18d3545da010b2f6066aeaf90bf442d4"

meta-efl/recipes-efl/efl/evas-generic-loaders_svn.bb

@@ -0,0 +1,11 @@
+require ${BPN}.inc
+
+SRCREV = "${EFL_SRCREV}"
+PV = "1.2.0+svnr${SRCPV}"
+PR = "${INC_PR}.0"
+DEFAULT_PREFERENCE = "-1"
+
+SRC_URI = "\
+  ${E_SVN}/trunk;module=${SRCNAME};protocol=http;scmdata=keep \
+"
+S = "${WORKDIR}/${SRCNAME}"