connman: added recipe libconnman-qt

This recipe provides the Qt library and QML plugins for connman. MJ: exported INSTALL_ROOT to fix build with dash MJ: dropped AUTOREV MJ: dropped TAG and replaced with SRCREV for 0.4.0 Signed-off-by: Felipe F. Tonello <ftonello@cercacor.com> Acked-by: Otavio Salvador <otavio@ossystems.com.br> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
2026-05-07 05:10:20 +00:00 · 2013-02-11 17:25:53 +00:00
parent cb4ac55a33
commit f4052df881
2 changed files with 106 additions and 0 deletions
@@ -0,0 +1,37 @@
+From 3850acef7d914a22e3fc4130ad43b2cc47338d6f Mon Sep 17 00:00:00 2001
+From: "Felipe F. Tonello" <ftonello@cercacor.com>
+Date: Mon, 7 Jan 2013 17:13:22 -0800
+Subject: [PATCH] added flags to disable qml plugin and test program to
+ compile
+
+This is usefull when there is no need to compile test program and qml plugin.
+
+Upstream-Status: Accepted
+
+Signed-off-by: Felipe F. Tonello <ftonello@cercacor.com>
+---
+ connman-qt.pro |   11 ++++++++++-
+ 1 file changed, 10 insertions(+), 1 deletion(-)
+
+diff --git a/connman-qt.pro b/connman-qt.pro
+index 7d9ec99..425c41f 100644
+--- a/connman-qt.pro
+++ b/connman-qt.pro
+@@ -1,4 +1,13 @@
+ TEMPLATE = subdirs
+-SUBDIRS += libconnman-qt test plugin
+SUBDIRS += libconnman-qt
+ CONFIG += ordered
+ 
+# CONFIG flag to disable test program
+!notest {
+    SUBDIRS += test
+}
+
+# CONFIG flag to disable qml plugin
+!noplugin {
+    SUBDIRS += plugin
+}
+-- 
+1.7.9.5
+
@@ -0,0 +1,69 @@
+DESCRIPTION = "Qt Library for ConnMan"
+HOMEPAGE = "https://github.com/nemomobile/libconnman-qt"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://libconnman-qt/clockmodel.h;endline=8;md5=ea9f724050803f15d2d900ce3c5dac88"
+
+SECTION = "qt/lib"
+
+PR = "r0"
+
+inherit qt4x11 pkgconfig
+
+RDEPENDS_${PN} = "connman"
+RDEPENDS_${PN}-plugin = "${PN}"
+
+PROVIDES += "${PN}-plugin"
+
+PACKAGES =+ "${PN}-plugin ${PN}-plugin-dbg"
+RRECOMMENDS_${PN} = "${PN}-plugin"
+
+BRANCH = "master"
+# this matches 0.4.0 tag
+SRCREV = "3af5bd38d82255942f582398160a5d3354346ca3"
+
+SRC_URI = " \
+  git://github.com/nemomobile/${PN}.git;branch=${BRANCH} \
+  file://0001-added-flags-to-disable-qml-plugin-and-test-program-t.patch \
+"
+
+S = "${WORKDIR}/git"
+
+QT_IMPORTS_DIR = "${libdir}/qt4/imports"
+# the plugin target needs to be the same as 'target.path' and 'qmldir.path' in ${S}/plugin/plugin.pro
+PLUGINS_TARGET = "${QT_IMPORTS_DIR}/MeeGo/Connman"
+
+EXTRA_QMAKEVARS_PRE = " \
+  CONFIG+=notest \
+"
+
+do_configure_prepend() {
+  # Hack *.pro variables
+  find ${S}/plugin/*.pro -exec sed -i -e 's,$$\[QT_INSTALL_IMPORTS\],${QT_IMPORTS_DIR},g' '{}' ';'
+}
+
+do_install() {
+  export INSTALL_ROOT=${D}
+  oe_runmake install
+}
+
+FILES_${PN} = " \
+  ${libdir}/libconnman-qt4${SOLIBS} \
+"
+
+FILES_${PN}-dev = " \
+  ${includedir}/connman-qt/* \
+  ${libdir}/libconnman-qt4${SOLIBSDEV} \
+  ${libdir}/libconnman-qt4.prl \
+  ${libdir}/pkgconfig/connman-qt4.pc \
+  ${libdir}/connman-qt4.pc \
+"
+
+FILES_${PN}-plugin = " \
+  ${PLUGINS_TARGET}/qmldir \
+  ${PLUGINS_TARGET}/lib*.so \
+"
+
+FILES_${PN}-plugin-dbg = " \
+  ${PLUGINS_TARGET}/.debug \
+  ${PLUGINS_TARGET}/.debug/* \
+"