mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 04:17:25 +00:00
Mariano Lopez
6bdf80f70b
The current recipe make no difference between the source and the build directory. There are source files outside this directory and isn't possible to patch these files. This changes adds the build directory path to the recipe, now is possible to patch files in other directories, if required. Signed-off-by: Mariano Lopez <mariano.lopez@linux.intel.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
47 lines
1.5 KiB
BlitzBasic
47 lines
1.5 KiB
BlitzBasic
HOMEPAGE = "http://w1.fi/hostapd/"
|
|
SECTION = "kernel/userland"
|
|
LICENSE = "GPLv2 | BSD"
|
|
LIC_FILES_CHKSUM = "file://${B}/README;md5=4d53178f44d4b38418a4fa8de365e11c"
|
|
DEPENDS = "libnl openssl"
|
|
SUMMARY = "User space daemon for extended IEEE 802.11 management"
|
|
|
|
inherit update-rc.d systemd
|
|
INITSCRIPT_NAME = "hostapd"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "hostapd.service"
|
|
SYSTEMD_AUTO_ENABLE_${PN} = "disable"
|
|
|
|
SRC_URI = " \
|
|
http://w1.fi/releases/hostapd-${PV}.tar.gz \
|
|
file://defconfig \
|
|
file://init \
|
|
file://hostapd.service \
|
|
"
|
|
|
|
S = "${WORKDIR}/hostapd-${PV}"
|
|
B = "${WORKDIR}/hostapd-${PV}/hostapd"
|
|
|
|
do_configure() {
|
|
install -m 0644 ${WORKDIR}/defconfig ${B}/.config
|
|
}
|
|
|
|
do_compile() {
|
|
export CFLAGS="-MMD -O2 -Wall -g -I${STAGING_INCDIR}/libnl3"
|
|
make
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${B}/hostapd.conf ${D}${sysconfdir}
|
|
install -m 0755 ${B}/hostapd ${D}${sbindir}
|
|
install -m 0755 ${B}/hostapd_cli ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
|
|
install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service
|
|
}
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/hostapd.conf"
|
|
|
|
SRC_URI[md5sum] = "69f9cec3f76d74f402864a43e4f8624f"
|
|
SRC_URI[sha256sum] = "8e272d954dc0d7026c264b79b15389ec2b2c555b32970de39f506b9f463ec74a"
|