mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-05-07 05:10:20 +00:00
Wang Mingyu
38402132a9
Changelog: ========== - Fix bad cast in release-gather collectives that caused data loss issues on Big-Endian 64b arches (s390x) - Fix issue with canceling MPI_ANY_SOURCE receive requests - Fix configuration issue when C++ compiler does not support complex types - Fix function signature issue in Hydra PBS support - Fix crash in MPI_Allreduce with MPI_LOGICAL type - Fix potential crash in multi-nic libfabric initialization - Fix memory leaks in Level Zero and PMIx support - Fix bug in CMA code when GPU support is enabled - Fix potential shared memory collision between multiple singleton processes on the same node - Add large count and other necessary aliases to ROMIO to avoid accidental profiling of internal MPI function usage - Add missing error checks in rndv and colletive composition code - Improve autogen.sh error message when autotools are too old Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
68 lines
2.2 KiB
BlitzBasic
68 lines
2.2 KiB
BlitzBasic
SUMMARY = "Message Passing Interface (MPI) implementation"
|
|
HOMEPAGE = "http://www.mpich.org/"
|
|
SECTION = "devel"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=3a296dfb961b957b0e8adf67d8478d3d"
|
|
|
|
SRC_URI = "http://www.mpich.org/static/downloads/${PV}/mpich-${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "8c1832a13ddacf071685069f5fadfd1f2877a29e1a628652892c65211b1f3327"
|
|
|
|
RDEPENDS:${PN} += "bash perl libxml2"
|
|
|
|
EXTRA_OECONF = "--enable-debuginfo \
|
|
--enable-fast \
|
|
--enable-shared \
|
|
--with-pm=gforker \
|
|
BASH_SHELL='${USRBINPATH}/env bash' \
|
|
PERL='${USRBINPATH}/env perl' \
|
|
--with-device=ch3:nemesis \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
|
|
PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx"
|
|
PACKAGECONFIG[fortran] = "--with-cross=${WORKDIR}/cross_values.txt --enable-fortran,--disable-f77 --disable-fortran,libgfortran"
|
|
|
|
# libmpi.so needs symbols like __multf3 and somehow it does not respect --rtlib option passed by clang
|
|
LDFLAGS:append:x86-64 = " -lgcc"
|
|
LDFLAGS:append:x86 = " -lgcc"
|
|
|
|
inherit autotools gettext pkgconfig qemu
|
|
|
|
DEPENDS += "qemu-native"
|
|
|
|
do_configure() {
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'fortran', '1', '', d)}" = "1" ]; then
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
|
|
cat > ${WORKDIR}/qemuwrapper << EOF
|
|
#!/bin/sh
|
|
$qemu_binary "\$@"
|
|
EOF
|
|
chmod +x ${WORKDIR}/qemuwrapper
|
|
|
|
sed -i 's:my \(.*\) ./t`;:my \1 ${WORKDIR}/qemuwrapper ${WORKDIR}/t`;:' ${S}/maint/gen_cross.pl
|
|
|
|
cd ${WORKDIR}
|
|
perl ${S}/maint/gen_cross.pl
|
|
|
|
sed -i 's:\(CROSS_F90_INTEGER_MODEL_MAP=.*\) }"$:\1 }, ":' ${WORKDIR}/cross_values.txt
|
|
fi
|
|
|
|
cd ${S}
|
|
./autogen.sh
|
|
|
|
cd ${B}
|
|
oe_runconf
|
|
sed -i -e 's,${WORKDIR},,g' ${B}/src/include/mpichinfo.h
|
|
}
|
|
|
|
do_install:append() {
|
|
sed -i 's,${S}/,,g' ${D}/${libdir}/libmpi.la
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicxx
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${DEBUG_PREFIX_MAP},,g' ${D}/${libdir}/pkgconfig/mpich.pc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicc
|
|
sed -i 's,${RECIPE_SYSROOT},/,g' ${D}${bindir}/mpicxx
|
|
}
|