mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-11-13 03:37:15 +00:00
Khem Raj
f3da02099d
Release notes: https://github.com/fastapi/fastapi/releases * opentelemetry-api is now a runtime dependency * Add opentelemetry-sdk and git to ptest dependencies, used by the new telemetry and translation script tests * Ignore telemetry tests that need logfire, the opentelemetry OTLP exporter and the opentelemetry fastapi instrumentation, which are not packaged in meta-python * Fixes the ptest hang in test_frontend_dependency_restores_existing_dependency_stacks with starlette 1.10, fixed upstream in 0.142.0 Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
55 lines
1.9 KiB
BlitzBasic
55 lines
1.9 KiB
BlitzBasic
SUMMARY = "FastAPI framework"
|
|
DESCRIPTION = "FastAPI framework, high performance, easy to learn, fast to code, ready for production"
|
|
HOMEPAGE = "https://fastapi.tiangolo.com/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=95792ff3fe8e11aa49ceb247e66e4810"
|
|
|
|
SRC_URI[sha256sum] = "6a22c1e2e6e32e0633ee7e170f00009a29b8228b16feb219ee42f32fd8d88a8f"
|
|
|
|
SRC_URI += "file://run-ptest"
|
|
|
|
CVE_PRODUCT = "tiangolo:fastapi"
|
|
|
|
inherit pypi python_pdm ptest-python-pytest
|
|
|
|
PACKAGECONFIG ?= ""
|
|
# swagger-ui is in meta-webserver that meta-python does not depend upon
|
|
# Users can still enable it in their distros explicitly but its disabled
|
|
# by default
|
|
PACKAGECONFIG[swagger-ui] = ",,,swagger-ui"
|
|
|
|
RDEPENDS:${PN} += "\
|
|
python3-annotated-doc \
|
|
python3-fastapi-cli \
|
|
python3-json \
|
|
python3-opentelemetry-api \
|
|
python3-pydantic \
|
|
python3-starlette \
|
|
python3-typing-extensions \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += "\
|
|
git \
|
|
python3-coverage \
|
|
python3-httpx \
|
|
python3-opentelemetry-sdk \
|
|
python3-orjson \
|
|
python3-dirty-equals \
|
|
python3-pytest-httpx \
|
|
python3-python-multipart \
|
|
python3-sqlalchemy \
|
|
python3-trio \
|
|
"
|
|
|
|
do_install_ptest:append() {
|
|
install -d ${D}${PTEST_PATH}/scripts
|
|
cp -rf ${S}/scripts/* ${D}${PTEST_PATH}/scripts/
|
|
rm -rf ${D}${PTEST_PATH}/scripts/tests
|
|
cp -rf ${S}/docs_src ${D}${PTEST_PATH}/
|
|
echo "import sys; from pathlib import Path; sys.path.insert(0, str(Path(__file__).parent))" > ${D}${PTEST_PATH}/conftest.py
|
|
# these docs examples need python3-pydantic-settings, which meta-python
|
|
# doesn't package
|
|
rm -rf ${D}${PTEST_PATH}/docs_src/settings/app02_an_py310
|
|
rm -rf ${D}${PTEST_PATH}/docs_src/settings/app02_py310
|
|
}
|