mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 04:17:25 +00:00
Andreas Müller
f11bc988d7
This release contains various fixes / enhancements - from release announcement: * Meta-data API implementation. (and a few tools updated with support for it) * Correct GPL licence to LGPL for files needed to build libjack. * Remove FreeBoB backend (superseded by FFADO). * define JACK_LIB_EXPORT, useful for internal clients. * Mark jack_midi_reset_buffer as deprecated. * Add example systemd unit file * Signal to systemd when jackd is ready. * Set "seq" alsa midi driver to maximum resolution possible. * Fix loading internal clients from another internal client. * Code cleanup and various fixes. (too many to mention here, see git log for details) Backported patches can go. Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
46 lines
1.5 KiB
BlitzBasic
46 lines
1.5 KiB
BlitzBasic
DESCRIPTION = "jackdmp is a C++ version of the JACK low-latency audio \
|
|
server for multi-processor machines. It is a new implementation of the \
|
|
JACK server core features that aims in removing some limitations of \
|
|
the JACK1 design. The activation system has been changed for a data \
|
|
flow model and lock-free programming techniques for graph access have \
|
|
been used to have a more dynamic and robust system."
|
|
SECTION = "libs/multimedia"
|
|
|
|
LICENSE = "GPLv2 & LGPLv2.1"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://common/jack/control.h;beginline=2;endline=21;md5=e6df0bf30cde8b3b825451459488195d \
|
|
file://common/jack/jack.h;beginline=1;endline=19;md5=6b736ed6b810592b135480a5e853392e \
|
|
"
|
|
|
|
DEPENDS = "libsamplerate0 libsndfile1 readline"
|
|
|
|
SRC_URI = "git://github.com/jackaudio/jack2.git"
|
|
SRCREV = "37250ff470277f9947fbf3ba738f943053e30525"
|
|
PV = "1.9.13"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit waf pkgconfig
|
|
|
|
PACKAGECONFIG ??= "alsa"
|
|
PACKAGECONFIG[alsa] = "--alsa=yes,--alsa=no,alsa-lib"
|
|
# --dbus only stops building jackd -> add --classic
|
|
PACKAGECONFIG[dbus] = "--dbus --classic,,dbus"
|
|
PACKAGECONFIG[opus] = "--opus=yes,--opus=no,libopus"
|
|
|
|
# portaudio is for windows builds only
|
|
EXTRA_OECONF = "--portaudio=no"
|
|
|
|
PACKAGES =+ "libjack jack-server jack-utils"
|
|
|
|
RDEPENDS_jack-dev_remove = "${PN} (= ${EXTENDPKGV})"
|
|
|
|
FILES_libjack = "${libdir}/*.so.* ${libdir}/jack/*.so"
|
|
FILES_jack-server = " \
|
|
${datadir}/dbus-1/services \
|
|
${bindir}/jackdbus \
|
|
${bindir}/jackd \
|
|
"
|
|
FILES_jack-utils = "${bindir}/*"
|
|
|
|
FILES_${PN}-doc += " ${datadir}/jack-audio-connection-kit/reference/html/* "
|