drop files supporting shared source

classes/shared-source-provide.bbclass

@@ -1,38 +0,0 @@
-# In order to share the same source between multiple packages (.bb files), we
-# unpack and patch the X source here into a shared dir.
-#
-# Take a look at gcc-source.inc for the general structure of this
-
-# We require that "SOURCE_NAME" be set
-
-# nopackages.bbclass {
-deltask do_package
-deltask do_package_write_rpm
-deltask do_package_write_ipk
-deltask do_package_write_deb
-deltask do_package_qa
-deltask do_packagedata
-#}
-
-deltask do_configure
-deltask do_compile
-deltask do_install
-deltask do_populate_sysroot
-deltask do_populate_lic
-deltask do_rm_work
-
-
-# override to get rid of '-native' or other misc
-# XXX: consider ${PR}
-PN = "${SOURCE_NAME}-source-${PV}"
-WORKDIR = "${TMPDIR}/work-shared/${SOURCE_NAME}-${PV}-${PR}"
-SSTATE_SWSPEC = "sstate:${SOURCE_NAME}::${PV}:${PR}::${SSTATE_VERSION}:"
-
-STAMP = "${STAMPS_DIR}/work-shared/${SOURCE_NAME}-${PV}-${PR}"
-STAMPCLEAN = "${STAMPS_DIR}/work-shared/${SOURCE_NAME}-${PV}-*"
-
-INHIBIT_DEFAULT_DEPS = "1"
-DEPENDS = ""
-PACKAGES = ""
-
-EXCLUDE_FROM_WORLD = "1"

classes/shared-source-use.bbclass

@@ -1,23 +0,0 @@
-# gcc's shared source code disables fetch (via the commented code below). We
-# can't do that because rust.bb currently fetches a rustc-snapshot archive itself.
-#do_fetch() {
-#	:
-#}
-#do_fetch[noexec] = "1"
-
-# gcc does `deltask` do_unpack. We avoid this so that the depends work sanely
-# (things that need source code can still be ordered after do_unpack).
-# As a side effect, we can also unpack things that aren't shared.
-# Note: just setting this normally doesn't work. Use of python() is required.
-python () {
-	d.setVarFlag('do_unpack', 'cleandirs', '')
-}
-# Avoid disabling do_patch for the same reason.
-#deltask do_patch
-
-SRC_URI = ""
-
-S = "${TMPDIR}/work-shared/${SOURCE_NAME}-${PV}-${PR}"
-
-do_unpack[depends] += "${SOURCE_NAME}-source-${PV}:do_patch"
-do_populate_lic[depends] += "${SOURCE_NAME}-source-${PV}:do_unpack"

recipes-devtools/rust/rust-release.inc

@@ -1,6 +0,0 @@
-SRC_URI = "\
-	https://static.rust-lang.org/dist/rustc-${PV}-src.tar.gz;name=rust \
-"
-
-S = "${WORKDIR}/rustc-${PV}"
-

recipes-devtools/rust/rust-shared-source.inc

@@ -1,3 +0,0 @@
-inherit shared-source-use
-require rust-version.inc
-S .= "/rustc-${PV}"

recipes-devtools/rust/rust-source.bb

@@ -1,29 +0,0 @@
-# In order to share the same source between multiple packages (.bb files), we
-# unpack and patch the rustc source here into a shared dir.
-#
-# Take a look at gcc-source.inc for the general structure of this
-
-inherit shared-source-provide
-
-require rust-version.inc
-require rust-release.inc
-
-SRC_URI[rust.md5sum] = "a48fef30353fc9daa70b484b690ce5db"
-SRC_URI[rust.sha256sum] = "a4015aacf4f6d8a8239253c4da46e7abaa8584f8214d1828d2ff0a8f56176869"
-LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=eb87dba71cb424233bcce88db3ae2f1a"
-
-SRC_URI_append = "\
-        file://rust/0001-Add-config-for-musl-based-arm-builds.patch \
-        file://rust/0002-Target-add-default-target.json-path-libdir-rust-targ.patch \
-        file://rust/0003-mk-for-stage0-use-RUSTFLAGS-to-override-target-libs-.patch \
-        file://rust/0004-mk-add-missing-CFG_LIBDIR_RELATIVE.patch \
-        file://rust/0005-configure-support-bindir-and-extend-libdir-to-non-bl.patch \
-        file://rust/0006-std-thread_local-workaround-for-NULL-__dso_handle.patch \
-        file://rust/0007-mk-install-use-disable-rewrite-paths.patch \
-        file://rust/0008-Allow-overriding-crate_hash-with-C-crate_hash.patch \
-        file://rust/0009-mk-platform.mk-pass-C-crate_hash-to-builds.patch \
-        file://rust/0010-mk-allow-changing-the-platform-configuration-source-.patch \
-        file://rust/0011-Get-rid-of-the-.note-interpretation-of-rustc-dylib-m.patch \
-        file://rust-llvm/0001-Don-t-build-unittests.patch;patchdir=src/llvm \
-        file://rust-installer/0001-add-option-to-disable-rewriting-of-install-paths.patch;patchdir=src/rust-installer \
-"

recipes-devtools/rust/rust-version.inc

@@ -1,6 +0,0 @@
-# Note: if you adjust this, you'll also need to change the hashes in
-# rust-source.bb
-SOURCE_NAME = "rust"
-PV = "1.10.0"
-
-LICENSE = "MIT | Apache-2.0"