mirror of
https://git.yoctoproject.org/meta-security
synced 2026-07-16 03:47:21 +00:00
Jackie Huang
7373d476a4
XML Security Library is a C library based on LibXML2 and OpenSSL. Signed-off-by: Jackie Huang <jackie.huang@windriver.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "XML Security Library is a C library based on LibXML2"
|
|
DESCRIPTION = "\
|
|
XML Security Library is a C library based on \
|
|
LibXML2 and OpenSSL. The library was created with a goal to support major \
|
|
XML security standards "XML Digital Signature" and "XML Encryption". \
|
|
"
|
|
HOMEPAGE = "http://www.aleksey.com/xmlsec/"
|
|
DEPENDS = "libtool libxml2 libxslt openssl zlib libgcrypt gnutls nss nspr libgpg-error"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=352791d62092ea8104f085042de7f4d0"
|
|
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "http://www.aleksey.com/xmlsec/download/${BP}.tar.gz \
|
|
file://fix-ltmain.sh.patch \
|
|
file://change-finding-path-of-nss.patch \
|
|
file://makefile-ptest.patch \
|
|
file://xmlsec1-examples-allow-build-in-separate-dir.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "2f4944356b69ea14c18814d9248fbbd8"
|
|
SRC_URI[sha256sum] = "99a8643f118bb1261a72162f83e2deba0f4f690893b4b90e1be4f708e8d481cc"
|
|
|
|
inherit autotools-brokensep ptest pkgconfig
|
|
|
|
CFLAGS += "-I${STAGING_INCDIR}/nspr4 -I${STAGING_INCDIR}/nss3"
|
|
CPPFLAGS += "-I${STAGING_INCDIR}/nspr4 -I${STAGING_INCDIR}/nss3"
|
|
|
|
EXTRA_OECONF = "\
|
|
--with-nss=${STAGING_LIBDIR}/../.. --with-nspr=${STAGING_LIBDIR}/../.. \
|
|
"
|
|
|
|
FILES_${PN}-dev += "${libdir}/xmlsec1Conf.sh"
|
|
FILES_${PN}-dbg += "${PTEST_PATH}/.debug/*"
|
|
|
|
RDEPENDS_${PN}-ptest += "${PN}-dev"
|
|
INSANE_SKIP_${PN}-ptest += "dev-deps"
|
|
|
|
PTEST_EXTRA_ARGS = "top_srcdir=${S} top_builddir=${B}"
|
|
|
|
do_compile_ptest () {
|
|
oe_runmake -C ${S}/examples ${PTEST_EXTRA_ARGS} all
|
|
}
|
|
|
|
do_install_append() {
|
|
sed -i -e "s@${STAGING_DIR_HOST}@@g" ${D}${bindir}/xmlsec1-config
|
|
}
|
|
|
|
do_install_ptest () {
|
|
oe_runmake -C ${S}/examples DESTDIR=${D}${PTEST_PATH} ${PTEST_EXTRA_ARGS} install-ptest
|
|
}
|