meta-ti-test: Import the recipes-kernel recipes

We are moving the meta-arago-test layer to meta-ti-test.  This commit
imports all of the recipes under recipes-kernel.

Signed-off-by: Ryan Eatmon <reatmon@ti.com>

meta-ti-test/recipes-kernel/hwspinlocktest/files/0001-Fix-Makefile-for-to-build-with-yocto.patch

@@ -0,0 +1,46 @@
+From 0a085bff54c3f02c20412c5f5a4060c2acb20d4c Mon Sep 17 00:00:00 2001
+From: Judith Mendez <jm@ti.com>
+Date: Mon, 18 Nov 2024 10:26:55 -0600
+Subject: [PATCH 1/2] Fix Makefile for to build with yocto
+
+Fix Makefile that builds hwspinlocktest out-of-tree-module
+for yocto recipie to be able to build the module.
+
+Upstream-Status: Inactive-Upstream [private repo]
+Signed-off-by: Judith Mendez <jm@ti.com>
+---
+ Makefile | 18 ++++++++++--------
+ 1 file changed, 10 insertions(+), 8 deletions(-)
+
+diff --git a/Makefile b/Makefile
+index 23ee629..d8fe76d 100644
+--- a/Makefile
++++ b/Makefile
+@@ -3,15 +3,17 @@
+ # TI OMAP HwSpinlock Unit Test
+ #
+
+-obj-m = omap_hwspinlock_test.o
++obj-m := omap_hwspinlock_test.o
++
++SRC := $(shell pwd)
+
+ all:
+-ifeq ($(KERNELDIR),)
+-	@echo "Error: KERNELDIR not set, exiting..."
+-	@echo "Eg: make ARCH=arm CROSS_COMPILE=arm-linux-gnueabihf- KERNELDIR=<linux-kernel rootdir>"
+-	@exit 1
+-endif
+-	make ${MAKE_OPTS} -C $(KERNELDIR) M=$(PWD) modules
++	$(MAKE) -C $(KERNEL_SRC) M=$(SRC)
++
++modules_install:
++	$(MAKE) -C $(KERNEL_SRC) M=$(SRC) modules_install
+
+ clean:
+-	$(RM) -r *.o *.ko *.mod* *.dwo .*.dwo .*.cmd *.symvers modules.order
++	rm -f *.o *~ core .depend .*.cmd *.ko *.mod.c
++	rm -f Module.markers Module.symvers modules.order
++	rm -rf .tmp_versions Modules.symvers
+--
+2.47.0

meta-ti-test/recipes-kernel/hwspinlocktest/hwspinlocktest_0.1.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Build hwspinlock test as an external Linux kernel module"
+DESCRIPTION = "${SUMMARY}"
+LICENSE = "GPL-2.0-only | BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=bfa02c83df161e37647ee23a2c7eacd4"
+
+inherit module
+
+SRC_URI = "\
+    git://github.com/TexasInstruments/omap-hwspinlock-test;protocol=https;branch=master \
+    file://0001-Fix-Makefile-for-to-build-with-yocto.patch \
+"
+
+SRCREV = "1d154fbe5b56ef81045763f574c2098a35d6a8b8"
+
+# The inherit of module.bbclass will automatically name module packages with
+# "kernel-module-" prefix as required by the oe-core build environment.
+
+RPROVIDES:${PN} += "kernel-module-hwspinlocktest"

meta-ti-test/recipes-kernel/kernel-selftest/kernel-selftest-ti.inc

@@ -0,0 +1,53 @@
+# Tests not enabled:
+#   openat2 has buildpath errors
+
+TEST_LIST += "\
+    arm64 \
+    breakpoints \
+    capabilities \
+    cgroup \
+    clone3 \
+    core \
+    cpu-hotplug \
+    cpufreq \
+    efivarfs \
+    exec \
+    filesystems \
+    filesystems/binderfs \
+    filesystems/epoll \
+    firmware \
+    fpu \
+    ftrace \
+    futex \
+    gpio \
+    intel_pstate \
+    ipc \
+    kcmp \
+    kvm \
+    livepatch \
+    membarrier \
+    memfd \
+    mqueue \
+    mincore \
+    net \
+    net/mptcp \
+    ptrace \
+    resq \
+    rtc \
+    seccomp \
+    sigaltstack \
+    size \
+    tc-testing \
+    timers \
+    tmpfs \
+    tpm2 \
+    user_events \
+    vDSO \
+    watchdog \
+"
+
+TEST_LIST:append:bsp-ti-6_18 = " \
+    pci_endpoint \
+"
+
+INSANE_SKIP:${PN} += "staticdev textrel"

meta-ti-test/recipes-kernel/kernel-selftest/kernel-selftest.bbappend

@@ -0,0 +1,4 @@
+KERNEL_SELFTEST_TI = ""
+KERNEL_SELFTEST_TI:ti-soc = "kernel-selftest-ti.inc"
+
+require ${KERNEL_SELFTEST_TI}

meta-ti-test/recipes-kernel/pcitest/pcitest_5.10.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Linux Kernel PCI test"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+BRANCH = "ti-linux-5.10.y"
+SRCREV = "73aa709ca10103b61fba3a07471dbb4dcb56db45"
+SRC_URI = "git://git.ti.com/git/ti-linux-kernel/ti-linux-kernel.git;protocol=https;branch=${BRANCH}"
+
+do_compile () {
+	cd ${S}/tools/pci
+	${CC} ${CFLAGS} ${LDFLAGS} -o pcitest pcitest.c
+}
+
+do_install () {
+	install -d ${D}${bindir}
+	install -m 0755 ${S}/tools/pci/pcitest ${D}${bindir}
+	install -m 0755 ${S}/tools/pci/pcitest.sh ${D}${bindir}
+}