mirrors/meta-ti
1
0
Fork 0
mirror of https://git.yoctoproject.org/meta-ti synced 2026-04-20 19:53:43 +00:00
Code Issues Projects Releases Wiki Activity

ti-ipc-examples-linux: Add a recipe to build messageq app_host

Browse Source 
Add a recipe to build the Application Host (for A15 core) to demonstrate
IPC with remote processors through messageq firmware. Also package this
in the /usr/bin directory for testing IPC. This recipe only builds the
app_host, and the firmwares are available in ti-linux-firmware
repository.

Signed-off-by: Beleswar Padhi <b-padhi@ti.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>
This commit is contained in:
Beleswar Padhi
2025-08-19 15:53:48 +05:30
committed by Ryan Eatmon
parent cd2a61edf6
commit 667145ff7e
1 changed files with 65 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

65
meta-ti-extras/recipes-ti/ipc/ti-ipc-examples-linux_git.bb Normal file
View File

@@ -0,0 +1,65 @@
DESCRIPTION = "TI Inter Processor Communication (IPC) MessageQ Application for Linux Host"
require recipes-ti/ipc/ti-ipc-common.inc
require ti-ipc-rtos.inc
LICENSE = "BSD-3-Clause"
LIC_FILES_CHKSUM = "file://${S_ipc-examples}/src/makefile;beginline=1;endline=30;md5=a52324bd5033bb49ea07bade1244ac9a"
IPC_INSTALL_DIR = "${STAGING_DIR_TARGET}/usr/share/ti/ti-ipc-tree"
INHIBIT_PACKAGE_STRIP = "1"
DEPENDS = "ti-ipc ti-ipc-rtos ti-xdctools-native zip-native"
EX02_PATH = "examples/DRA7XX_linux_elf/ex02_messageq/host"
do_compile() {
cd ${S_ipc-examples}/src
oe_runmake .examples \
IPCTOOLS="${S_ipc-metadata}/src/etc"
for alt_platform in ${ALT_PLATFORM}; do
oe_runmake .examples "PLATFORM=${alt_platform}" \
IPCTOOLS="${S_ipc-metadata}/src/etc"
done
if [ "${PLATFORM}" != "UNKNOWN" ]; then
oe_runmake extract HOSTOS="linux" IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
if [ ! -z ${ALT_PLATFORM} ]; then
oe_runmake extract PLATFORM="${ALT_PLATFORM}" HOSTOS="linux" \
IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
fi
oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
IPC_INSTALL_DIR="${IPC_INSTALL_DIR}"
if [ ! -z ${ALT_PLATFORM} ]; then
oe_runmake -C ${EX02_PATH} all HOSTOS="linux" \
LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
PLATFORM="${ALT_PLATFORM}"
fi
fi
}
do_install() {
cd ${S_ipc-examples}/src
if [ "${PLATFORM}" != "UNKNOWN" ]; then
# Install directory for linux examples
install -d ${D}${bindir}/ipc/examples/ex02_messageq
oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq"
if [ ! -z ${ALT_PLATFORM} ]; then
oe_runmake -C ${EX02_PATH} install IPC_INSTALL_DIR="${IPC_INSTALL_DIR}" \
LINUX_SYSROOT_DIR="${STAGING_INCDIR}" \
HOSTOS="linux" EXEC_DIR="${D}/${bindir}/ipc/examples/ex02_messageq" \
PLATFORM="${ALT_PLATFORM}"
fi
fi
}
FILES:${PN} += "${bindir}/*"