ti-sci-fw: introduce recipe to package sources for MAINMACHINE

ti-sci-fw builds multiple config variants via multiconfig and the number
is expected to grow. Provide a recipe to package a single set of sources
for MAINMACHINE.

Signed-off-by: Denys Dmytriyenko <denys@ti.com>

recipes-bsp/ti-sci-fw/ti-sci-fw-source_2020.04.bb

@@ -0,0 +1,45 @@
+# ti-sci-fw builds and packages multiple config variants via multiconfig
+# Let's take a page from gcc-source as a common recipe for all gcc stages,
+# but also to provide a single package for MAINMACHINE of all multiconfigs
+
+require recipes-bsp/ti-sci-fw/ti-sci-fw_${PV}.inc
+
+SUMMARY += "- sources"
+
+COMPATIBLE_MACHINE = "k3"
+
+EXCLUDE_FROM_WORLD = "1"
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS = ""
+
+PACKAGES = "${PN}"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+SRCIPK_SRC_DIR = "${WORKDIR}/imggen"
+SRCIPK_INSTALL_DIR = "board-support/k3-image-gen-${PV}"
+FILES_${PN} = "${SRCIPK_INSTALL_DIR}"
+
+do_install() {
+    # Copy sources for packaging
+    mkdir -p ${D}/${SRCIPK_INSTALL_DIR}
+    if [ -e ${SRCIPK_SRC_DIR} ]; then
+        if [ "${SRCIPK_SRC_DIR}" = "${WORKDIR}" ]; then
+            excludes='--exclude ./temp --exclude ${D}'
+        fi
+        tar -C ${SRCIPK_SRC_DIR} -cO $excludes . | tar -C ${D}/${SRCIPK_INSTALL_DIR} -xpf -
+    fi
+
+    # Fix up patches/ directory to contain actual patches instead of symlinks
+    if [ -e ${D}/${SRCIPK_INSTALL_DIR}/patches ]
+    then
+        mv ${D}/${SRCIPK_INSTALL_DIR}/patches ${D}/${SRCIPK_INSTALL_DIR}/patches-links
+        cp -rL ${D}/${SRCIPK_INSTALL_DIR}/patches-links ${D}/${SRCIPK_INSTALL_DIR}/patches
+        rm -rf ${D}/${SRCIPK_INSTALL_DIR}/patches-links
+    fi
+}
+
+# Do not perform any QA checks on source package
+INSANE_SKIP_${PN} += "${ALL_QA}"

recipes-bsp/ti-sci-fw/ti-sci-fw_2020.04.bb

@@ -1,7 +1,4 @@
-SUMMARY = "TI SCI firmware (SYSFW)"
-
-LICENSE = "TI-TFL"
-LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
+require recipes-bsp/ti-sci-fw/ti-sci-fw_${PV}.inc
 
 DEPENDS = "openssl-native u-boot-mkimage-native dtc-native"
 
@@ -17,18 +14,6 @@ PACKAGE_ARCH = "${MACHINE_ARCH}"
 TI_SECURE_DEV_PKG ?= ""
 export TI_SECURE_DEV_PKG
 
-SRCREV = "6b02b1ea07da65a68444e86439ad5b031e9fd5a2"
-BRANCH ?= "ti-linux-firmware"
-SRCREV_imggen = "a7d3909ed8ae23a7c90f7ef821713a8b0c3c061d"
-SRCREV_FORMAT = "imggen"
-
-SRC_URI = " \
-	git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=git;branch=${BRANCH} \
-	git://git.ti.com/k3-image-gen/k3-image-gen.git;protocol=git;branch=master;destsuffix=imggen;name=imggen \
-"
-
-S = "${WORKDIR}/git"
-
 SYSFW_SOC ?= "unknown"
 SYSFW_CONFIG ?= "unknown"
 

recipes-bsp/ti-sci-fw/ti-sci-fw_2020.04.inc

@@ -0,0 +1,16 @@
+SUMMARY = "TI SCI firmware (SYSFW)"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
+
+SRCREV = "6b02b1ea07da65a68444e86439ad5b031e9fd5a2"
+BRANCH ?= "ti-linux-firmware"
+SRCREV_imggen = "a7d3909ed8ae23a7c90f7ef821713a8b0c3c061d"
+SRCREV_FORMAT = "imggen"
+
+SRC_URI = " \
+	git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=git;branch=${BRANCH} \
+	git://git.ti.com/k3-image-gen/k3-image-gen.git;protocol=git;branch=master;destsuffix=imggen;name=imggen \
+"
+
+S = "${WORKDIR}/git"