ipc-transport-qmss: Add recipe for ipc qmss transport and test code

- Provides ipc transport layer using qmss module
- Supports k2h, k2k, k2e, k2l devices

Signed-off-by: Sam Nelson <sam.nelson@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>

recipes-ti/ipc/ipc-transport-qmss-test_git.bb

@@ -0,0 +1,31 @@
+include ipc-transport-qmss.inc
+
+DEPENDS = "ipc-transport-qmss ti-ipc"
+
+#FILES_${PN}-test = "${bindir}/multiProcessTest_*.out"
+
+CHOICELIST = "yes no"
+
+DEVICELIST = "k2h k2k k2e k2l"
+
+do_compile () {
+#   Now build the test code
+	for device in ${DEVICELIST}
+	do
+		for choice in ${CHOICELIST}
+		do
+			oe_runmake tests \
+				IPC_DEVKIT_INSTALL_PATH=${STAGING_INCDIR} \
+				USEDYNAMIC_LIB="$choice" DEVICE="$device"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		oe_runmake installbin \
+			INSTALL_BIN_BASE_DIR=${D}${bindir} DEVICE="$device"
+	done
+
+}

recipes-ti/ipc/ipc-transport-qmss.inc

@@ -0,0 +1,16 @@
+DESCRIPTION = "TI QMSS-Based IPC MessageQ Transport"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://COPYING.txt;md5=27bb0deb260c60120a8d7b91da7c3b02"
+
+BRANCH="master"
+SRC_URI = "git://git.ti.com/keystone-linux/ipc-transport.git;protocol=git;branch=${BRANCH}"
+# Below commit ID corresponds to DEV.IPC-TRANSPORT.01.00.00.00
+SRCREV = "b3077467126c84b5d583dc29e13ab221064b687b"
+PV = "01.00.00.00"
+
+COMPATIBLE_MACHINE = "keystone"
+
+S = "${WORKDIR}/git/linux/qmss"
+
+EXTRA_OEMAKE += "PDK_INSTALL_PATH=${STAGING_INCDIR} TRANS_QMSS_SRC_DIR=${S}"

recipes-ti/ipc/ipc-transport-qmss_git.bb

@@ -0,0 +1,14 @@
+include ipc-transport-qmss.inc
+
+DEPENDS = "ti-ipc mpm-transport"
+
+do_compile () {
+#   Now build the transport
+	oe_runmake clean
+	oe_runmake lib
+}
+
+do_install () {
+	oe_runmake install INSTALL_INC_BASE_DIR=${D}${includedir} \
+		INSTALL_LIB_BASE_DIR=${D}${libdir}
+}