mmap-lld; Add new recipe for mmap lld

- Provides memory map driver using Keystone MPAX module
- Test recipe is used to build test binaries using the mmap lld library
- Supports k2h, k2k & k2e

Signed-off-by: Sam Nelson <sam.nelson@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>

recipes-bsp/mmap-lld/mmap-lld-test_git.bb

@@ -0,0 +1,40 @@
+DESCRIPTION = "TI KEYSTONE MMAP driver test binaries "
+include mmap-lld.inc
+
+DEPENDS="common-csl-ip mmap-lld"
+RDEPENDS_${PN}="uio-module-drv"
+
+DEVICELIST = "k2h \
+              k2k \
+              k2e \
+"
+
+CHOICELIST = " yes \
+               no \
+"
+
+do_compile () {
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 clean \
+			PDK_INSTALL_PATH="${STAGING_INCDIR}" \
+			DEVICE="$device" MPAX_SRC_DIR="${S}"
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples \
+				PDK_INSTALL_PATH=${STAGING_INCDIR} \
+				DEVICE="$device" MPAX_SRC_DIR="${S}" \
+				USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 installbin \
+		PDK_INSTALL_PATH=${STAGING_INCDIR} \
+		DEVICE="$device" MPAX_SRC_DIR="${S}" \
+		INSTALL_BIN_BASE_DIR="${D}/${bindir}"
+	done
+}

recipes-bsp/mmap-lld/mmap-lld.inc

@@ -0,0 +1,16 @@
+LICENSE = "BSD-3-Clause"
+
+COMPATIBLE_MACHINE = "keystone"
+
+LIC_FILES_CHKSUM = "file://COPYING.txt;md5=b3315b8190036fe1c6a8263d02e15606"
+
+
+BRANCH="master"
+SRC_URI = "git://git.ti.com/keystone-rtos/mmap-lld.git;destsuffix=git/ti/runtime/mmap;protocol=git;branch=${BRANCH}"
+# Commit correspond to DEV.MMAP.02.00.00.03
+SRCREV = "601f9284c392f67bb7f69ed1a5df5231a43c3137"
+
+PV="2.0.0"
+PR = "r0"
+
+S = "${WORKDIR}/git/ti/runtime/mmap"

recipes-bsp/mmap-lld/mmap-lld_git.bb

@@ -0,0 +1,12 @@
+DESCRIPTION = "TI KEYSTONE mmap driver using Keystone MPAX Programming"
+include mmap-lld.inc
+
+DEPENDS="common-csl-ip"
+
+do_compile () {
+	make -f makefile_armv7 clean lib PDK_INSTALL_PATH=${STAGING_INCDIR}
+}
+
+do_install () {
+	make -f makefile_armv7 install PDK_INSTALL_PATH=${STAGING_INCDIR} INSTALL_INC_BASE_DIR=${D}/${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+}