mirrors/poky
1
0
Fork 0
mirror of https://git.yoctoproject.org/poky synced 2026-05-08 17:19:20 +00:00
Code Issues Projects Releases Wiki Activity

tar: merge tar.inc into tar recipe

Browse Source 
There's only one user of tar.inc (meta-gplv2 has its own copy), so
merge the .inc file into the tar recipe.

(From OE-Core rev: cce7b627f9046c15dde49c001481003cee33fc9c)

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Andre McCurdy
2018-04-26 10:49:40 -07:00
committed by Richard Purdie
parent d49bfa2eae
commit b6c35d1c5b
2 changed files with 61 additions and 63 deletions
Download Patch File Download Diff File Expand all files Collapse all files
meta/recipes-extended/tar/tar.inc
-52
View File
@@ -1,52 +0,0 @@
SUMMARY = "GNU file archiving program"
DESCRIPTION = "GNU tar saves many files together into a single tape \
or disk archive, and can restore individual files from the archive."
HOMEPAGE = "http://www.gnu.org/software/tar/"
SECTION = "base"
SRC_URI = "${GNU_MIRROR}/tar/tar-${PV}.tar.bz2"
inherit autotools gettext texinfo
EXTRA_OECONF += "DEFAULT_RMT_DIR=${base_sbindir}"
# Let aclocal use the relative path for the m4 file rather than the
# absolute since tar has a lot of m4 files, otherwise there might
# be an "Argument list too long" error when it is built in a long/deep
# directory.
acpaths = "-I ./m4"
do_install () {
autotools_do_install
ln -s tar ${D}${bindir}/gtar
}
do_install_append_class-target() {
if [ "${base_bindir}" != "${bindir}" ]; then
install -d ${D}${base_bindir}
mv ${D}${bindir}/tar ${D}${base_bindir}/tar
mv ${D}${bindir}/gtar ${D}${base_bindir}/gtar
rmdir ${D}${bindir}/
fi
}
PACKAGES =+ "${PN}-rmt"
FILES_${PN}-rmt = "${base_sbindir}/rmt*"
inherit update-alternatives
ALTERNATIVE_PRIORITY = "100"
ALTERNATIVE_${PN} = "tar"
ALTERNATIVE_${PN}-rmt = "rmt"
ALTERNATIVE_${PN}_class-nativesdk = ""
ALTERNATIVE_${PN}-rmt_class-nativesdk = ""
ALTERNATIVE_LINK_NAME[tar] = "${base_bindir}/tar"
ALTERNATIVE_LINK_NAME[rmt] = "${base_sbindir}/rmt"
PROVIDES_append_class-native = " tar-replacement-native"
NATIVE_PACKAGE_PATH_SUFFIX = "/${PN}"
BBCLASSEXTEND = "native nativesdk"
meta/recipes-extended/tar/tar_1.30.bb
+61 -11
View File
@@ -1,18 +1,68 @@
require tar.inc
PACKAGECONFIG ??= ""
PACKAGECONFIG[acl] = "--with-posix-acls, --without-posix-acls, acl,"
SUMMARY = "GNU file archiving program"
DESCRIPTION = "GNU tar saves many files together into a single tape \
or disk archive, and can restore individual files from the archive."
HOMEPAGE = "http://www.gnu.org/software/tar/"
SECTION = "base"
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
SRC_URI += "file://remove-gets.patch \
file://musl_dirent.patch \
"
SRC_URI = "${GNU_MIRROR}/tar/tar-${PV}.tar.bz2 \
file://remove-gets.patch \
file://musl_dirent.patch \
"
SRC_URI[md5sum] = "8404e4c1fc5a3000228ab2b8ad674a65"
SRC_URI[sha256sum] = "87592b86cb037c554375f5868bdd3cc57748aef38d6cb741c81065f0beac63b7"
do_install_append_libc-musl() {
rm -f ${D}${libdir}/charset.alias
rmdir ${D}${libdir}
inherit autotools gettext texinfo
PACKAGECONFIG ??= ""
PACKAGECONFIG[acl] = "--with-posix-acls,--without-posix-acls,acl"
EXTRA_OECONF += "DEFAULT_RMT_DIR=${base_sbindir}"
# Let aclocal use the relative path for the m4 file rather than the
# absolute since tar has a lot of m4 files, otherwise there might
# be an "Argument list too long" error when it is built in a long/deep
# directory.
acpaths = "-I ./m4"
do_install () {
autotools_do_install
ln -s tar ${D}${bindir}/gtar
}
do_install_append_class-target() {
if [ "${base_bindir}" != "${bindir}" ]; then
install -d ${D}${base_bindir}
mv ${D}${bindir}/tar ${D}${base_bindir}/tar
mv ${D}${bindir}/gtar ${D}${base_bindir}/gtar
rmdir ${D}${bindir}/
fi
}
do_install_append_libc-musl() {
rm -f ${D}${libdir}/charset.alias
rmdir ${D}${libdir}
}
PACKAGES =+ "${PN}-rmt"
FILES_${PN}-rmt = "${base_sbindir}/rmt*"
inherit update-alternatives
ALTERNATIVE_PRIORITY = "100"
ALTERNATIVE_${PN} = "tar"
ALTERNATIVE_${PN}-rmt = "rmt"
ALTERNATIVE_${PN}_class-nativesdk = ""
ALTERNATIVE_${PN}-rmt_class-nativesdk = ""
ALTERNATIVE_LINK_NAME[tar] = "${base_bindir}/tar"
ALTERNATIVE_LINK_NAME[rmt] = "${base_sbindir}/rmt"
PROVIDES_append_class-native = " tar-replacement-native"
NATIVE_PACKAGE_PATH_SUFFIX = "/${PN}"
BBCLASSEXTEND = "native nativesdk"