mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 12:49:46 +00:00
Chen Qi
3e1b79a762
Previously, 'pidof' utility has two providers, sysvinit and procps, and both have the same priority 200. Fix procps to lower the priority of its 'pidof' to 150 to avoid conflict. (From OE-Core rev: 468f9c9899016c46635c9f39eef3483303a5be81) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.5 KiB
BlitzBasic
68 lines
2.5 KiB
BlitzBasic
SUMMARY = "System and process monitoring utilities"
|
|
DESCRIPTION = "Procps contains a set of system utilities that provide system information about processes using \
|
|
the /proc filesystem. The package includes the programs ps, top, vmstat, w, kill, and skill."
|
|
HOMEPAGE = "https://gitorious.org/procps"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2+ & LGPLv2+"
|
|
LIC_FILES_CHKSUM="file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
|
|
"
|
|
|
|
DEPENDS = "ncurses"
|
|
|
|
inherit autotools gettext pkgconfig update-alternatives
|
|
|
|
SRC_URI = "http://downloads.sourceforge.net/project/procps-ng/Production/procps-ng-${PV}.tar.xz \
|
|
file://sysctl.conf \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "957e42e8b193490b2111252e4a2b443c"
|
|
SRC_URI[sha256sum] = "6ed65ab86318f37904e8f9014415a098bec5bc53653e5d9ab404f95ca5e1a7d4"
|
|
|
|
S = "${WORKDIR}/procps-ng-${PV}"
|
|
|
|
EXTRA_OECONF = "--enable-skill --disable-modern-top"
|
|
|
|
CPPFLAGS += "-I${S}"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${base_bindir}
|
|
[ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
|
|
install -d ${D}${base_sbindir}
|
|
[ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
|
|
if [ "${base_sbindir}" != "${sbindir}" ]; then
|
|
rmdir ${D}${sbindir}
|
|
fi
|
|
|
|
install -d ${D}${sysconfdir}
|
|
install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${sysconfdir}/sysctl.d
|
|
ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
|
|
fi
|
|
}
|
|
|
|
CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"
|
|
|
|
bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime"
|
|
base_bindir_progs += "kill pidof ps watch"
|
|
base_sbindir_progs += "sysctl"
|
|
|
|
ALTERNATIVE_PRIORITY = "200"
|
|
ALTERNATIVE_PRIORITY[pidof] = "150"
|
|
|
|
ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"
|
|
|
|
ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
|
|
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
|
|
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"
|
|
|
|
python __anonymous() {
|
|
for prog in d.getVar('base_bindir_progs').split():
|
|
d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir'), prog))
|
|
|
|
for prog in d.getVar('base_sbindir_progs').split():
|
|
d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir'), prog))
|
|
}
|
|
|